Как получить флаг админа в эвенте ?

[x330122]

Всем привет народ.
Мне нужна помощь с получением админ флага в событии "player_death", вот я пытался делать но безуспешно. Кто подскажет что делать ? :ac:
Оффтоп

else if (GetAdminFlag(victim, ADMFLAG_CUSTOM6);
{
CPrintToChat(attacker, "{cyan}Вы убили админа. Приготовься к анальной каре :)");
}

 

[White Wolf]

@Tetragromaton, полный код в студию.
Оффтоп

Зачем выделять весь текст полужирным?
Зачем использовать оффтоп, если есть спойлер?

 

[inklesspen]

stock bool CheckAdminChar(int client, const char[] cflag)
{
    if(GetUserAdmin(client)==INVALID_ADMIN_ID)
        return false
    new AdminFlag:flag
    if(FindFlagByChar(cflag[0], flag))
        return GetAdminFlag(GetUserAdmin(client), flag)
    return false
}

Спасибо White

 

[x330122]

stock bool CheckAdminChar(int client, const char[] cflag)
{
    if(GetUserAdmin(client)==INVALID_ADMIN_ID)
        return false
    new AdminFlag:flag
    if(FindFlagByChar(cflag[0], flag))
        return GetAdminFlag(GetUserAdmin(client), flag)
    return false
}

Спасибо White

Эм, и что мне с ним делать ?

 

[inklesspen]

Эм, и что мне с ним делать ?

Вставить в конец плагина и в твоем эвенте пихнуть такую проверку:
CheckAdminChar(client, flag)
Например
CheckAdminChar(client, "z")

 

[AlmazON]

CheckAdminChar

stock bool CheckAdminFlags(int client, const char[] cflag)
{
    return view_as<bool>(GetUserFlagBits(client) & ReadFlagString(cflag));
}

Можно указывать сразу несколько админ-флагов (латинские буквы).

получением админ флага в событии "player_death"

Флаги нужно получать при входе игрока и хранить результат в переменной!

 

[pashek71]

stock bool CheckAdminFlags(int client, const char[] cflag)
{
    return GetUserFlagBits(client) & ReadFlagString(cflag);
}

Извиняюсь за ап старой темы, но не работает данный кусок кода, пишет tag mismatch

 

[AlmazON]

пишет tag mismatch

Поправил. Либо просто можно было исправить bool на int.

 

[R1KO]

Поправил. Либо просто можно было исправить bool на int.

Интересно почему логическое выражение возвращает инт

 

[AlmazON]

почему

Потому, что так теги совпадают, нет ошибки. Оффтоп

А с остальным найдут применение сами.

 

[Grey83]

@R1KO, потому что выражение забыли в круглые скобки закрыть return (GetUserFlagBits(client) & ReadFlagString(cflag));

 

[R1KO]

@Grey83, дело не в этом. проверил

 

[Grey83]

@R1KO, а как ты определил какой тип возвращает функция?

 

[R1KO]

@Grey83, зачем? для функции задал тип bool и посмотрел на возврат в разных вариантах, в обоих было несоответствие тегов.

Короче я понял. туплю.
int & int = int

 

[inklesspen]

@Grey83, зачем? для функции задал тип bool и посмотрел на возврат в разных вариантах, в обоих было несоответствие тегов.

Короче я понял. туплю.
int & int = int

Битовое значение само выражается в int

 

[HooLIGUN]

Подскажите, как здесь сделать проверку на админа именно по флагу b, сейчас как я понял здесь по всем флагам проверяется

public OnClientPostAdminCheck(client)
{
    if (enabled && !IsFakeClient(client))
    {
        adminid[client] = GetUserAdmin(client);
            
        if (adminallow && adminid[client] != INVALID_ADMIN_ID)
        {
            decl String:steam_id[64];
            decl String:player_ip[64];
    
            GetClientIP(client, player_ip, sizeof(player_ip));
            GetClientAuthString(client, steam_id, sizeof(steam_id));
            
            if (announce)
                PrintToChatAll("%t", "AdminJoined", 4, 3, client, 4, 3, player_ip, 4, 3, steam_id);
        }
        else if (Steam_IsConnected())
            LookupPlayerGroups(client);
    }
}

вышеуказанные методы не сработали (может не правильно вставил). Так же код компилирую на sm 1.6.3 , так как плагин старый.

 

[Kruzya]

@HooLIGUN,

public OnClientPostAdminCheck(client)
{
    if (enabled && !IsFakeClient(client))
    {
        adminid[client] = GetUserAdmin(client);
        if (adminallow && (GetUserFlagBits(client) & ADMFLAG_GENERIC) == ADMFLAG_GENERIC)
        {
            decl String:steam_id[64];
            decl String:player_ip[64];

            GetClientIP(client, player_ip, sizeof(player_ip));
            GetClientAuthString(client, steam_id, sizeof(steam_id));

            if (announce)
                PrintToChatAll("%t", "AdminJoined", 4, 3, client, 4, 3, player_ip, 4, 3, steam_id);
        }
        else if (Steam_IsConnected())
            LookupPlayerGroups(client);
    }
}

 

[Grey83]

HooLIGUN, 7-ю строку заменить на

if(adminallow && adminid[client] != INVALID_ADMIN_ID && (GetAdminFlag(adminid[client], ADMFLAG_GENERIC) || GetAdminFlag(adminid[client], ADMFLAG_GENERIC, Access_Real))

Сообщения автоматически склеены: 3 Ноя 2019

PrintToChatAll("%t", "AdminJoined", 4, 3, client, 4, 3, player_ip, 4, 3, steam_id);
Интересно, а нафига всем светить IP и SteamID админа?

Сообщения автоматически склеены: 3 Ноя 2019

if (adminallow && (GetUserFlagBits(client) & ADMFLAG_GENERIC) == ADMFLAG_GENERIC)

А разве не достаточно того, что GetUserFlagBits(client) & ADMFLAG_GENERIC не равно 0?
Насколько я понимаю так отфильтрируются все, у кого есть какие-либо иные флаги помимо ADMFLAG_GENERIC

 

[HooLIGUN]

Оффтоп

PrintToChatAll("%t", "AdminJoined", 4, 3, client, 4, 3, player_ip, 4, 3, steam_id);
Интересно, а нафига всем светить IP и SteamID админа?

Не знаю, это задумка автора плагина, у меня это отключено.
Что то не пойму,как ответить по нику, раньше на ник или аватарку можно было кликнуть.

 

[Kruzya]

А разве не достаточно того, что GetUserFlagBits(client) & ADMFLAG_GENERIC не равно 0?

Вообще, достаточно. Но я так делаю везде и всегда на тот случай, если кому-то понадобится проверять несколько флагов.