Обратный отсчёт

[Nekro]

Приветствую, подскажите.
Есть команда, активация который запускает таймер. Вопрос, как узнать сколько осталось времени до старта таймера?

Handle hTimerCmd[MAXPLAYERS+1];

public void OnPluginStart()
{
    RegConsoleCmd("sm_cmd", cmd);
}

public Action cmd(int iClient, any args)
{
    hTimerCmd[iClient] = CreateTimer(100.0, TimerCmd, iClient);
}

public Action TimerCmd(Handle hTimer, int iClient)
{
    PrintToChat(iClient, "Время истекло");
}

 

[Tomiks]

Самое первое что приходит в голову - создать таймер на 1.0 секунду, который будет это считать(ну получается два таймера одновременно).
А так вроде бы в апи сурсмода нельзя получить то, сколько прошло с момента старта таймера.

Ещё один вариант - записываешь через GetTime() время запуска таймера и где надо делаешь GetTime() - записанное_время_старта_таймера; и получаешь сколько секунд прошло, только таким образом доли секунд не посмотреть

 

[Nekro]

Самое первое что приходит в голову - создать таймер на 1.0 секунду, который будет это считать(ну получается два таймера одновременно).
А так вроде бы в апи сурсмода нельзя получить то, сколько прошло с момента старта таймера.

Ещё один вариант - записываешь через GetTime() время запуска таймера и где надо делаешь GetTime() - записанное_время_старта_таймера; и получаешь сколько секунд прошло, только таким образом доли секунд не посмотреть

int[] iTimeCmd = new int[MaxClients + 1];
if(bEnable[iClient]) iTimeCmd[iClient] = GetTime();
PrintHintText(iClient, "Вам необходимо выждать [%d] секунд", GetTime() - iTimeCmd[iClient]);

Выдаёт огромные значения

Сообщения автоматически склеены: 12 Сен 2021

Проблема была в локальном массиве

 

[romeo7]

Handle g_hTimerCmd[MAXPLAYERS+1];
int g_iCountdown[MAXPLAYERS+1];

public void OnPluginStart()
{
    RegConsoleCmd("sm_cmd", cmd);
}

public Action cmd(int iClient, any args)
{
    g_iCountdown[iClient] = 100;
 
    if(g_hTimerCmd[iClient] != INVALID_HANDLE)
    {
        KillTimer(g_hTimerCmd[iClient]);
        g_hTimerCmd[iClient] = INVALID_HANDLE;
    }
    g_hTimerCmd[iClient] = CreateTimer(1.0, TimerCmd, GetClientUserId(iClient), TIMER_REPEAT);
}

public Action TimerCmd(Handle hTimer, int userid)
{
    int iClient = GetClientOfUserId(userid);
 
    if(iClient)
    {
        g_iCountdown[iClient]--;
    
        if(g_iCountdown[iClient] <= 0)
        {
            // Your code here
            PrintToChat(iClient, "Время истекло");
        
            g_hTimerCmd[iClient] = INVALID_HANDLE;
            return Plugin_Stop;
        }
    
        PrintHintText(iClient, "Вам необходимо выждать [%i] секунд", g_iCountdown[iClient]);
    }
 
    return Plugin_Continue;
}

 

[Сергей68]

@romeo7, В твоем исполнение таймеру требуется устанавливать время 1.0 иначе оно не будет работать как ты задумал, точнее будет но с задержкой в 100 секунд.
Убивать таймер через delete/killtimer внутри самого таймера нельзя.

Handle g_hTimerCmd[MAXPLAYERS+1];
int g_iCountdown[MAXPLAYERS+1];

public void OnPluginStart()
{
    RegConsoleCmd("sm_cmd", cmd);
}

public Action cmd(int iClient, any args)
{
    g_iCountdown[iClient] = 100;
 
    if(g_hTimerCmd[iClient] != null)
        delete g_hTimerCmd[iClient]

    g_hTimerCmd[iClient] = CreateTimer(1.0, TimerCmd, GetClientUserId(iClient), TIMER_REPEAT);
}

public Action TimerCmd(Handle hTimer, int UserId)
{
    int iClient = GetClientOfUserId(UserId);
    if(!iClient)
        return Plugin_Stop;

    if(--g_iCountdown[iClient] > 0)
    {
        PrintHintText(iClient, "Вам необходимо выждать [%i] секунд", g_iCountdown[iClient]);
        return Plugin_Continue;
    }

    PrintToChat(iClient, "Время истекло");

    g_hTimerCmd[iClient] = null;
    return Plugin_Stop;
}

 

[romeo7]

@romeo7, требуется устанавливать время 1.0

забыл изменить

Сообщения автоматически склеены: 12 Сен 2021

@romeo7, Убивать таймер через delete/killtimer внутри самого таймера нельзя.

Зачем? Скопировал этот код из старого рабочего плагина и не хотел тратит время для Plugin_Stop.

 

[Grey83]

Зачем? Скопировал этот код из старого рабочего плагина и не хотел тратит время для Plugin_Stop.

а потом придёшь жаловаться на ошибки в логах?
Тем более там у тебя return;, хотя должен возращаться Action.

 

[Madness aka null138]

// время допустим 61.5 секунд.

static float endTime;

function()
{
    endTime = GetGameTime() + 61.5;
    CreateTimer(61.5, TimerFunction, _, TIMER_FLAG_NO_MAPCHANGE);
}

// получить оставщееся время

float timeLeft = endTime - GetGameTime();
print("%f", timeLeft);