Отсчёт времени до начала раунда

[pokypka20]

Помогите составить код: (понятия не имею как делать)

Допустим у меня стоит mp_freezetime 3, помогите сделать чтобы во время фриз тайм происходил отчёт в центре экрана до начала раунда.

Приготовьтесь к бою: 3
Приготовьтесь к бою: 2
Приготовьтесь к бою: 1

Заранее спасибо.

 

[AlmazON]

pokypka20, хукаешь событие начала раунда и с него запускаешь повторяющийся таймер. Время окончания приравниваешь к mp_freezetime. Давал же код таймера.

в центре экрана

Хинт или выше, крупнее?
Оффтоп

Помогите

Помогаю. Либо прямо пиши: "Напишите мне весь код".

Спойлер

new sec;

public OnPluginStart() HookEvent("round_start", Event_RoundStart, EventHookMode_PostNoCopy);

public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
	sec = GetConVarInt(FindConVar("mp_freezetime"));
	CreateTimer(1.0, AreYouReady, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Action:AreYouReady(Handle:timer)
{
	if (--sec > 0)
	{
		PrintHintTextToAll("Приготовьтесь к бою: %d", sec);
		return Plugin_Continue;
	}
	return Plugin_Stop;
}

Хинт видят все, даже наблюдатели. Из-за того, что ты не хочешь видеть 0, хинт будет висеть секунды 3 на 1.

 

[pokypka20]

AlmazON, Спасибо, помогло. Если возможно подскажите можно ли каждый секунде присвоить свой текст? каждой секунде таймера тоесть.

Приготовьтесь к бою: 3 --> Закупаемся
Приготовьтесь к бою: 2 --> Разминаемся
Приготовьтесь к бою: 1 --> Побежали

примерно так.

 

[AlmazON]

каждый секунде присвоить свой текст

Элементарно, например, через условия:

if (sec == 3) PrintHintTextToAll("Приготовьтесь к бою: 3 --> Закупаемся");
else if (sec == 2) PrintHintTextToAll("Приготовьтесь к бою: 2 --> Разминаемся");
else if (sec == 1) PrintHintTextToAll("Приготовьтесь к бою: 1 --> Побежали");

 

[TolikCorp]

new sec;
public OnPluginStart() HookEvent("round_start", Event_RoundStart, EventHookMode_PostNoCopy);
public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    sec = GetConVarInt(FindConVar("mp_freezetime"));
    CreateTimer(1.0, AreYouReady, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}
public Action:AreYouReady(Handle:timer)
{
    if (--sec > 0)
    {
        switch(sec)
        {
            case 1:PrintHintTextToAll("Приготовьтесь к бою: %d --> Побежали", sec);
            case 2:PrintHintTextToAll("Приготовьтесь к бою: %d --> Разминаемся", sec);
            case 3:PrintHintTextToAll("Приготовьтесь к бою: %d --> Закупаемся", sec);
            default:PrintHintTextToAll("Приготовьтесь к бою: %d", sec);
        }
        return Plugin_Continue;
    }
    return Plugin_Stop;
}

 

[AlmazON]

iItem

Это ещё откуда? А так нормально, если он вообще понял, как устроен switch...
Оффтоп

Нет смысла извлекать время ещё раз - этим ты теряешь всё преимущество switch'а.

 

[TolikCorp]

Да забыл удалить) щас ок)

 

[AlmazON]

Оффтоп

забыл удалить

Сразу видно, слизал откуда-то, а не писал по памяти)

 

[pokypka20]

Элементарно, например, через условия:

if (sec == 3) PrintHintTextToAll("Приготовьтесь к бою: 3 --> Закупаемся");
else if (sec == 2) PrintHintTextToAll("Приготовьтесь к бою: 2 --> Разминаемся");
else if (sec == 1) PrintHintTextToAll("Приготовьтесь к бою: 1 --> Побежали");

Работает, спасибо.

 

[AlmazON]

pokypka20, лучше вообще так, если надписей много (3 и более):

Спойлер

new sec;

public OnPluginStart() HookEvent("round_start", Event_RoundStart, EventHookMode_PostNoCopy);

public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
	sec = GetConVarInt(FindConVar("mp_freezetime"));
	CreateTimer(1.0, AreYouReady, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Action:AreYouReady(Handle:timer)
{
	if (--sec > 0)
	{
		decl String:t[50];
		switch(sec)
		{
			case 1: t = " --> Побежали";
			case 2: t = " --> Разминаемся";
			case 3: t = " --> Закупаемся";
			default: t[0] = '\0';
		}
		PrintCenterTextAll("Приготовьтесь к бою: %d%s", sec, t);
		return Plugin_Continue;
	}
	return Plugin_Stop;
}

Это крупно, немного выше центра.

 

[pokypka20]

pokypka20, лучше вообще так, если надписей много (3 и более):

Спойлер

new sec;

public OnPluginStart() HookEvent("round_start", Event_RoundStart, EventHookMode_PostNoCopy);

public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
	sec = GetConVarInt(FindConVar("mp_freezetime"));
	CreateTimer(1.0, AreYouReady, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Action:AreYouReady(Handle:timer)
{
	if (--sec > 0)
	{
		decl String:t[50];
		switch(sec)
		{
			case 1: t = " --> Побежали";
			case 2: t = " --> Разминаемся";
			case 3: t = " --> Закупаемся";
			default: t[0] = '\0';
		}
		PrintCenterTextAll("Приготовьтесь к бою: %d%s", sec, t);
		return Plugin_Continue;
	}
	return Plugin_Stop;
}

Это крупно, немного выше центра.

Я использую sedhud в любом углу экрана :)

 

[The End Is Near...]

new const String:message[][] = {"закупаемся", "разминаемся", "побежали"};

// В OnPluginStart получаем значение переменной, т.к. нет смысла каждый раунд ее получать

// ...
PrintHintTextToAll("приготовьтесь к бою: %d. %s", sec, message[sec - 1]);

 

[AlmazON]

При старте плагина переменную получать?!
Приравниваем, получаем 3 (у него так), таймер минусует и получаем 0. Дальше что? С 0 уже работать не будет. Значение то надо возвращать.
А со строкой хорошо придумал) Но, не к месту! Сообщение не отображается вовсе, когда пытаются извлечь и показать несуществующий индекс строки.
Хоть я и добил сей факт, но, в итоге, получается также или, может даже хуже по оптимизации.

"закупаемся", "разминаемся", "побежали"

Надо указывать в обратном порядке.