Вручную распределить игроков по командам

[GermanIvanov]

Задумка заключается в том, чтобы скрыть окно выбора тима, а сразу запускать человека в игру, после входа в которую он автоматически присоединяется к команде по некоему признаку. В качестве примера возьмем ситуацию при которой все боты записываются в террористов, а все люди в контру.

Сначала я пытался перехватывать public OnClientPostAdminCheck(client) и оттуда вызывать ChangeClientTeam(client,team); Команда вроде срабатывала, окно выбора исчезало но после старта карты игрок оказывался в Unassign team.

Следующим шагом я попытался перехватить OnMapStart и там развести народ по своим местам.
public OnMapStart()
{
int team = 0;
for(new client = 1; client < MaxClients; client++)
if(IsClientInGame(client) && IsClientConnected(client))
{
GetClientAuthId(client, AuthId_Steam2, steamid, sizeof(steamid));
if(strcmp(steamid,"BOT")){ team=2;}else{team=3;}
ChangeClientTeam(client,team);
}
}

Ничего не произошло. Я пробовал вместо ChangeClientTeam использовать CS_SwitchTeam но она также не срабатывала.

Никто не подскажет, может следует перехватывать какое то другое cобытие, а не OnMapStart ?

 

[AlmazON]

public OnClientPostAdminCheck(client)

Самое то.

после старта карты

Вызов выше идёт после каждой карты, когда игрок почти полностью подключён.

игрок оказывался в Unassign team

Не знаю, откуда вдруг такая проблема. С ботами/людьми или со всеми сразу?

может следует перехватывать какое то другое cобытие

Событие player_spawn идёт ещё позже всех стандартных вызовов SM. Но, лучше уж тогда player_activate для разового переброса при подключении игрока.

 

[R1KO]

как вариант отловить vgui с именем team, заблокировать его и переместить игрока в нужную команду

 

[GermanIvanov]

Не знаю, откуда вдруг такая проблема. С ботами/людьми или со всеми сразу?

с людьми, точнее со мной одним локальным во время отлаживания скрипта. может в обработчике не возвращаю в return что то нужное?

Но, лучше уж тогда player_activate

ага, спасибо попробую и отпишусь.

отловить vgui с именем team, заблокировать его

так далеко я еще не продвинулся в скрипте. Это как делается можно пример?

 

[AlmazON]

может в обработчике не возвращаю в return что то нужное?

Все описанные здесь вызовы/события не требуют дополнительных "мучений".
Если тебе вообще нужно запретить выбор команды и после:

все боты записываются в террористов, а все люди в контру

То через:

AddCommandListener(Callback, "jointeam");

В обратном вызове перекидываешь в нужную команду. Оффтоп

Требуется return Plugin_Handled; в конце кода.

 

[GermanIvanov]

--- Добавлено позже ---

Событие player_spawn идёт ещё позже всех стандартных вызовов SM. Но, лучше уж тогда player_activate для разового переброса при подключении игрока.

Спасибо получилось!!! :drinks:
player_spawn - как выяснилось еще рано, а вот player_activate в самый раз. Игрок на несколько секунд вывешивается в unsigned, а затем переключается в террориста. Для тех кто будет набивать шишки вслед за мной вот рабочий код без излишеств.

#include <sourcemod>
#define VERSION "1.0.0"
#define NAME "usercheck"
public Plugin:myinfo =
{
   name = NAME,
   author = "German",
   description = "Valid User checker",
   version = VERSION,
   url = ""
};
public OnPluginStart()
{
   HookEvent("player_activate", EventPlayerActivate);
}
public Action:EventPlayerActivate(Handle:event, const String:playername[], bool:dontBroadcast)
{
   int team = 0;
   decl String:steamid[32];
   int client = GetClientOfUserId(GetEventInt(event, "userid"));
   GetClientAuthId(client, AuthId_Steam2, steamid, sizeof(steamid));
   if(strcmp(steamid,"BOT")){
     team=CS_TEAM_T;     
   } else {
     team=CS_TEAM_CT;
 
}
ChangeClientTeam(client,team);
  
}

 

[AlmazON]

Игрок на несколько секунд вывешивается в unsigned, а затем переключается в террориста

Может, просто таймер стоило добавить на 1 секунду.

 

[MaZa]

//// AutoTeam.sp
//
// AutoTeam.sp(23) : error 017: undefined symbol "CS_TEAM_T"
// AutoTeam.sp(25) : error 017: undefined symbol "CS_TEAM_CT"
// AutoTeam.sp(28) : warning 217: loose indentation
//
// 2 Errors.
//
// Compilation Time: 0,86 sec
// ----------------------------------------

 

[Grey83]

@MaZa_Mladwii, там инклюда #include <cstrike> в начале плагина не хватает
--- Добавлено позже ---
Вот тебе действительно без лишнего :ab:

#include <cstrike>

public Plugin myinfo =
{
    name        = "usercheck",
    author        = "German",
    description    = "Valid User checker",
    version        = "1.0.1",
    url            = ""
};

public void OnPluginStart()
{
    HookEvent("player_activate", EventPlayerActivate);
}

public void EventPlayerActivate(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));
    if(client) ChangeClientTeam(client, IsFakeClient(client) ? CS_TEAM_T : CS_TEAM_CT);
}

:ps: Раз начал использовать новый синтаксис, то используй его во всём плагине, а не в паре строчек

 

[GermanIvanov]

Может, просто таймер стоило добавить на 1 секунду.

в принципе наверно можно, но это уже в финальной версии плагина.

Раз начал использовать новый синтаксис, то используй его во всём плагине, а не в паре строчек

Ага, так по-современней выглядит. А где нибудь можно скачать полный мануал по языку текущей версии, а то я все больше язык изучаю по фрагментам чужих плагинов.

 

[Grey83]

@GermanIvanov, API
Статьи

 

[Vit_ amin]

@MaZa_Mladwii, там инклюда #include <cstrike> в начале плагина не хватает
--- Добавлено позже ---
Вот тебе действительно без лишнего :ab:

#include <cstrike>

public Plugin myinfo =
{
    name        = "usercheck",
    author        = "German",
    description    = "Valid User checker",
    version        = "1.0.1",
    url            = ""
};

public void OnPluginStart()
{
    HookEvent("player_activate", EventPlayerActivate);
}

public void EventPlayerActivate(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));
    if(client) ChangeClientTeam(client, IsFakeClient(client) ? CS_TEAM_T : CS_TEAM_CT);
}

:ps: Раз начал использовать новый синтаксис, то используй его во всём плагине, а не в паре строчек

#pragma newdecls required - и тебе даже не стоит говорить о новом синтаксисе ...

 

[Grey83]

@Vit_ amin,Оффтоп

так это сам автор должен добавлять.
У меня во всех моих плагинах с новым синтаксисом это добавлено
А здесь плагин из 5 строчек: и проверять практически нечего, всё на экране свободно помещается

Кстати, если убрать инклюд, то можно выиграть порядка 70 байт.
А если убрать инфу о версии, авторе, то ещё байт 50. :ab:

 

[AlmazON]

if(client) ChangeClientTeam(client, IsFakeClient(client) ? CS_TEAM_T : CS_TEAM_CT);

Можно и так замутить:

ChangeClientTeam(client, CS_TEAM_CT - view_as<int>(IsFakeClient(client)));

Проверки вообще не нужны. Оффтоп

Первая то уж точно.

 

[Grey83]

@AlmazON, при неверном UserID client будет равен "0"
поэтому и добавил на всякий пожарный
А выбор команды сделан так для более удобного редактирования: так проще значения менять