[CS: GO] Надо написать один короткий плагин(Сделано)

[ComfortableZmServ]

Нужно заблокировать использование прицела на aug, цену в лс.

Контакты:
Vladislav Shlyakhter

 

[Grey83]

заблочить правую кнопку, чтобы нельзя было включить зум на ауге?

 

[AlmazON]

заблочить правую кнопку

Даже не думай - бесполезная затея! Уже давно было испробовано - проскальзывает прицел на полсекунды. Только:

SetEntPropFloat(weapon, Prop_Send, "m_flNextSecondaryAttack", 9999999.9);

Оффтоп

Только хардкор.

 

[ComfortableZmServ]

заблочить правую кнопку, чтобы нельзя было включить зум на ауге?

да

 

[Grey83]

как-то так

public void OnPluginStart()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(client)) OnClientPutInServer(i);
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_WeaponSwitchPost, OnWeaponSwitch);
}

public void OnClientDisconnect(int client)
{
    SDKUnhook(client, SDKHook_WeaponSwitchPost, OnWeaponSwitch);
}

public void OnWeaponSwitch(int client, int weapon)
{
    static char class[32];
    if(GetEdictClassname(weapon, class, sizeof(class)) && StrContains(class, "aug") !=-1) SetEntPropFloat(weapon, Prop_Send, "m_flNextSecondaryAttack", 3600.0);
}

Думаю часа хватит: кто будет целый час бегать и не переключать оружие, чтобы только взглянуть в прицел?! =)

 

[AlmazON]

SDKHook(client, SDKHook_WeaponSwitchPost, OnWeaponSwitch);

Слабенько, очень. После каждого выстрела значение сбросится, как и при перезарядке, так и при поднятии (да-да, "свитча" и тут недосточно - багует разок-другой). Ещё при спавне с оружием - отдельная история.

public void OnClientDisconnect(int client)
{
SDKUnhook(client, SDKHook_WeaponSwitchPost, OnWeaponSwitch);

SDK сам унхукнет свои хуки, когда объект "уничтожается" (игрок выходит, в данном случае).

 

[Grey83]

ну тогда придётся юзать OnPlayerRunCmd:

public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float vel[3], float angles[3], int &weapon, int &subtype, int &cmdnum, int &tickcount, int &seed, int mouse[2])
{
    if (IsPlayerAlive(client))
    {
        if (buttons & IN_ATTACK2)
        {
            static char class[32];
            GetClientWeapon(client, class, sizeof(class));
            if(StrContains(class, "aug") != -1)
            {
                SetEntPropFloat(weapon, Prop_Send, "m_flNextSecondaryAttack", 3600.0);
                buttons &= ~IN_ATTACK2;
                return Plugin_Changed;
            }
        }
    }
    return Plugin_Continue;
}

Или так (если передаётся индекс энтити оружия, а не его тип):

public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float vel[3], float angles[3], int &weapon, int &subtype, int &cmdnum, int &tickcount, int &seed, int mouse[2])
{
    if (IsPlayerAlive(client))
    {
        if(buttons & IN_ATTACK2)
        {
            static char class[32];
            if(GetEntityClassname(weapon, class, sizeof(class)) && StrContains(class, "aug") != -1)
            {
                SetEntPropFloat(weapon, Prop_Send, "m_flNextSecondaryAttack", 3600.0);
                buttons &= ~IN_ATTACK2;
                return Plugin_Changed;
            }
        }
    }
    return Plugin_Continue;
}

 

[AlmazON]

придётся юзать OnPlayerRunCmd

проскальзывает прицел на полсекунды

1) Сначала появится, исчезнет и заблокируется...
2) Выстрел - значение сброшено. См. пункт 1.
Адекватно поможет только от "спама" прицелом.

 

[R1KO]

ну тогда придётся юзать OnPlayerRunCmd

в SDKHook_PostThink

static char class[32];
if(GetEntityClassname(weapon, class, sizeof(class)) && StrContains(class, "aug") != -1)
{
SetEntPropFloat(weapon, Prop_Send, "m_flNextSecondaryAttack", 3600.0);
buttons &= ~IN_ATTACK2;
return Plugin_Changed;
}

 

[Grey83]

@R1KO, в смысле вот так?

public void OnPluginStart()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(client)) OnClientPutInServer(i);
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_PostThink, OnClientPostThink);
}

public void OnClientPostThink(int client)
{
    static char class[32];
    class[0] = '\0';
    GetClientWeapon(client, class, sizeof(class));    // функция всегда определяет тип оружия?
    if(class[0] && StrContains(class, "aug") !=-1) SetEntPropFloat(weapon, Prop_Send, "m_flNextSecondaryAttack", 3600.0);
}

 

[akvorok.ego]

@R1KO, в смысле вот так?

public void OnPluginStart()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(client)) OnClientPutInServer(i);
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_PostThink, OnClientPostThink);
}

public void OnClientPostThink(int client)
{
    static char class[32];
    class[0] = '\0';
    GetClientWeapon(client, class, sizeof(class));    // функция всегда определяет тип оружия?
    if(class[0] && StrContains(class, "aug") !=-1) SetEntPropFloat(weapon, Prop_Send, "m_flNextSecondaryAttack", 3600.0);
}

Зачем чистить массив, а потом ещё и проверять?

Спойлер: Код

public void OnPluginStart()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i)) OnClientPutInServer(i);
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_PostThink, OnClientPostThink);
}


public void OnClientPostThink(int client)
{
    static char class[20];
    if(GetClientWeapon(client, class, 20) && StrContains(class, "aug") != -1) SetEntPropFloat(GetEntPropEnt(client, Prop_Data, "m_hActiveWeapon"), Prop_Send, "m_flNextSecondaryAttack", 3600.0);
}

 

[Grey83]

Зачем чистить массив, а потом ещё и проверять?

На всякий случай

 

[R1KO]

StrContains(class, "aug") !=-1

в целях оптимизации лучше сделать так:

strcmp(class[7], "aug") == 0

 

[ComfortableZmServ]

Спасибо всем, кто решил помочь, да еще и бесплатно, чуть не забыл про эту тему.

p.s найс вы тут срач развели, правда по делу)))
p.p.s - p.s написал до того как прочитал ваши сообщения, блин вы просто мастера своего дела, всех в авторы впишу, но вам наверное насрать))