Нужен плагин на выдачу дефолт ножа

[ilyuxa12321]

Здравствуйте.
У меня из-за конфликта двух плагинов пропадает моделька ножа.
Но если дропнуть этот нож и выдать заного, то всё норм. (При свапе на грену тоже появляется нож, но не удобно очень).
Суть плагина: удалять у игрока при спавне предмет в определенном слоту и выдавать его заного.

 

[AlmazON]

выдавать его заного

Спойлер: [CS:GO/CS:S] Перевыдача ножа

#include <sdktools_functions>
#include <sdktools_entinput>

#pragma newdecls required

public void OnPluginStart()
{
	HookEvent("player_spawn", Event_PlayerSpawn);
}

public void Event_PlayerSpawn(Event event, const char[] name, bool donBroadcast)
{
	CreateTimer(0.1, ReloadKnife, event.GetInt("userid"), TIMER_FLAG_NO_MAPCHANGE);
}

public Action ReloadKnife(Handle timer, any userid)
{
	int client = GetClientOfUserId(userid);
	if (client)
	{
		int knife = GetPlayerWeaponSlot(client, 2);
		if (knife != -1)
		{
			RemovePlayerItem(client, knife);
			AcceptEntityInput(knife, "Kill");
		}
		GivePlayerItem(client, "weapon_knife");
	}
	return Plugin_Stop;
}

 

[ilyuxa12321]

Спойлер: [CS:GO/CS:S] Перевыдача ножа

#include <sdktools_functions>
#include <sdktools_entinput>

#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("player_spawn", Event_PlayerSpawn);
}

public void Event_PlayerSpawn(Event event, const char[] name, bool donBroadcast)
{
    CreateTimer(0.1, ReloadKnife, event.GetInt("userid"), TIMER_FLAG_NO_MAPCHANGE);
}

public Action ReloadKnife(Handle timer, any userid)
{
    int client = GetClientOfUserId(userid);
    if (client)
    {
        int knife = GetPlayerWeaponSlot(client, 2);
        if (knife != -1)
        {
            RemovePlayerItem(client, knife);
            AcceptEntityInput(knife, "Kill");
        }
        GivePlayerItem(client, "weapon_knife");
    }
    return Plugin_Stop;
}

Спасибо, работает, но только если таймер ставить на 3.0, вместо 0.1.
UPD: хотя на 1.0 поставил тоже работает. Очень благодарен

 

[AlmazON]

только если таймер ставить на 3.0, вместо 0.1

Это уже "по вкусу". Нужно ставить то же время или чуть большее, чем то, после которого скрывается нож. Оффтоп

Если в проблемных плагинах стоит по 0.1, то в этом ставить 0.2-0.3.

 

[SlipknotRU]

@AlmazON, зачем таймер? узнаем есть ли нож в руках и выдаем, на крайний случай, постспавн флаг, удаляем все оружие у игрока при спавне и выдаем нож.

 

[ilyuxa12321]

@AlmazON, зачем таймер? узнаем есть ли нож в руках и выдаем, на крайний случай, постспавн флаг, удаляем все оружие у игрока при спавне и выдаем нож.

Нож то есть, моделька куда-то исчезает переодически, а так с этим плагином перевыдача и норм, моделька есть, после каждого спавна