Плагин скина

[Erik]

Попытался сам написать плагин вот такой, но что то то работает то нет, таймер ставил для того чтобы он не конфликтовал с другими плагинами на скины которые даются в начале раунда
Оффтоп

#include <cstrike>
#include <sdktools>

#define MAX_CLIENTS 129

public OnMapStart()
{
PrecacheModel("models/player/custom_player/step_one_ru/jb/zek_1/zek.mdl");
}

public OnPluginStart()
{
HookEvent("player_spawn", Event_PlayerSpawn);
}

public Action:Event_PlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
CreateTimer(0.2, Timer_Qweerti_tarantino, _, TIMER_FLAG_NO_MAPCHANGE);
}

public Action Timer_Qweerti_tarantino(Handle hTimer, any UserId)
{
if (GetUserFlagBits(i) & ADMFLAG_ROOT) {
for (new i = 1; i <= MaxClients; i++) {
if (IsClientInGame(i) && IsPlayerAlive(i) && GetClientTeam(i) == CS_TEAM_T)
{
SetEntityModel(i, "models/player/custom_player/step_one_ru/jb/zek_1/zek.mdl");
PrintToChat(i, " \x02Скин установлен для игрока Qwerti Tarantino");
}
}
}
}

 

[Reiko1231]

#include <sdktools>
#include <cstrike>

public OnMapStart()
{
   PrecacheModel("models/player/custom_player/step_one_ru/jb/zek_1/zek.mdl");
}

public OnPluginStart()
{
   HookEvent("player_spawn", Event_PlayerSpawn);
}

public Action:Event_PlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
   // передаем userid появившегося игрока в таймер
   CreateTimer(0.2, Timer_Qweerti_tarantino, GetEventInt(event, "userid"), TIMER_FLAG_NO_MAPCHANGE);
}

public Action Timer_Qweerti_tarantino(Handle:hTimer, any:userid)
{
   // получаем индекс игрока
   new client = GetClientOfUserId(userid);
   // проверяем, что он всё ещё на сервере (GetClientOfUserId вернет 0, если игрок вышел) и прочие проверки
   if (client && GetUserFlagBits(client) & ADMFLAG_ROOT && IsPlayerAlive(client) && GetClientTeam(client) == CS_TEAM_T) {
       SetEntityModel(client, "models/player/custom_player/step_one_ru/jb/zek_1/zek.mdl");
       PrintToChat(client, " \x02Скин установлен для игрока Qwerti Tarantino");
   }
}