SDKHook_SetTransmit

[Nekro]

Такая дилемма, SDKHook отрабатывает, но проверка работы OnTransmit молчит.. Подскажите ошибку

#include <sdkhooks>
#include <sdktools>

public void OnPluginStart()
{
    RegConsoleCmd("sm_t", CmdSpawnEnt);
}

public void OnMapStart()
{
    PrecacheModel("materials/file.vmt");
}

public Action CmdSpawnEnt(int client, any args)
{
    float fPos[3];
    GetClientEyePosition(client, fPos)
    int iEntity = CreateEntityByName("env_sprite_oriented");
    DispatchKeyValue(iEntity, "classname", "env_sprite_oriented");
    DispatchKeyValue(iEntity, "model", "materials/file.vmt");
    DispatchKeyValueVector(iEntity, "origin", fPos);
    SetEntPropEnt(iEntity, Prop_Send, "m_hOwnerEntity", client);
    SDKHook(iEntity, SDKHook_SetTransmit, OnTransmit);
    DispatchSpawn(iEntity);
    TeleportEntity(iEntity, fPos, NULL_VECTOR, NULL_VECTOR);
    return Plugin_Changed;
}

public Action OnTransmit(int iEntity, int client)
{
    PrintToChatAll("[%d]", iEntity);
    return Plugin_Changed;
}

 

[Nebraska]

float fPos[3];
GetClientEyePosition(client, fPos);
int iEntity = CreateEntityByName("env_sprite_oriented");
if (iEntity != -1)
{
    DispatchKeyValue(iEntity, "classname", "env_sprite_oriented");
    DispatchKeyValue(iEntity, "model", "materials/file.vmt");
    DispatchKeyValueVector(iEntity, "origin", fPos);
    SetEntPropEnt(iEntity, Prop_Send, "m_hOwnerEntity", client);
   
    if (DispatchSpawn(iEntity))
    {
        SDKHook(iEntity, SDKHook_SetTransmit, OnTransmit);
    }
}

 

[Nekro]

float fPos[3];
GetClientEyePosition(client, fPos);
int iEntity = CreateEntityByName("env_sprite_oriented");
if (iEntity != -1)
{
    DispatchKeyValue(iEntity, "classname", "env_sprite_oriented");
    DispatchKeyValue(iEntity, "model", "materials/file.vmt");
    DispatchKeyValueVector(iEntity, "origin", fPos);
    SetEntPropEnt(iEntity, Prop_Send, "m_hOwnerEntity", client);
  
    if (DispatchSpawn(iEntity))
    {
        SDKHook(iEntity, SDKHook_SetTransmit, OnTransmit);
    }
}

Без изменений, реакции от OnTransmit нет

 

[GoDtm666]

Попробуйте через таймер или на следующем фрейме хук сделать.

 

[Nekro]

Попробуйте через таймер или на следующем фрейме хук сделать.

Попробовал и через фрейм и через таймер с секундной задержкой, никакой реакции от OnTransmit

 

[Reidenshi]

v34? Работать не будет, я все перепробовал

 

[Nekro]

v34? Работать не будет, я все перепробовал

Css OB

 

[Grey83]

@GoDtm666, прикол в том, что в практически одинаковом коде (и класс энтити совпадает) в разных плагинах SDKHook_SetTransmit может как работать, так и не работать.
Если что я про свои Server WH и Revival говорю, как пример. В обоих случаях вешается хук на спрайты, но в Server WH хук работает как положено, а в Revival (в разное время раза три, не меньше, пытался реализовать) - не работает.

Сообщения автоматически склеены: 23 Окт 2022

Даже код работы с хуками можно сравнить:

Revival

2/2 подсказку по среди экрана Что за подсказка? Скрин бы хотя бы. Вообще неплохо бы было ещё указать игру. Кмк, у квара sm_revival_hud_mode стоит значение 1 (если это так, то положение надписи выставляется кварами sm_revival_hud_x и sm_revival_hud_y) или 2 (если игра - CS:GO).

hlmod.ru

Server WH

Сильно переписанный плагин легального WallHack'а. Отрисовывает рамку вокруг живых игроков. Цвет зависит от команды (для каждой команды цвет задаётся кваром). Рамку могут видеть только мёртвые и команда наблюдателей (видимость...

hlmod.ru

 

[komashchenko]

#include <sdkhooks>
#include <sdktools>

public void OnPluginStart()
{
    RegConsoleCmd("sm_t", CmdSpawnEnt);
}

public void OnMapStart()
{
    PrecacheModel("materials/file.vmt");
}

Action CmdSpawnEnt(int client, any args)
{
    float fPos[3];
    GetClientEyePosition(client, fPos)
    int iEntity = CreateEntityByName("env_sprite_oriented");
    DispatchKeyValue(iEntity, "classname", "env_sprite_oriented");
    DispatchKeyValue(iEntity, "model", "materials/file.vmt");
    DispatchKeyValueVector(iEntity, "origin", fPos);
    SetEntPropEnt(iEntity, Prop_Send, "m_hOwnerEntity", client);
    DispatchSpawn(iEntity);
    SetEdictFlags(iEntity, GetEdictFlags(iEntity) & ~FL_EDICT_ALWAYS);
    SDKHook(iEntity, SDKHook_SetTransmit, OnTransmit);
    TeleportEntity(iEntity, fPos, NULL_VECTOR, NULL_VECTOR);
    
    return Plugin_Changed;
}

Action OnTransmit(int iEntity, int client)
{
    SetEdictFlags(iEntity, GetEdictFlags(iEntity) & ~FL_EDICT_ALWAYS);
    
    PrintToChatAll("[%d]", iEntity);
    
    return Plugin_Changed;
}

 

[Grey83]

DispatchSpawn(iEntity);
TeleportEntity(iEntity, fPos, NULL_VECTOR, NULL_VECTOR);

Поменяй местами, т.к. лучше делать TeleportEntity() до DispatchSpawn(): на АМ пишут, что может вызвать проблемы.

@komashchenko, если использовано DispatchKeyValueVector(iEntity, "origin", fPos);, то TeleportEntity(iEntity, fPos, NULL_VECTOR, NULL_VECTOR); уже вроде и не требуется (проверено не раз).

И ещё: м/б добавить ещё пару флагов которые будут выключаться на всякий случай?
Я про FL_EDICT_DONTSEND и FL_EDICT_PVSCHECK: SetEdictFlags(iEntity, GetEdictFlags(iEntity) & ~(FL_EDICT_ALWAYS|FL_EDICT_DONTSEND|FL_EDICT_PVSCHECK));

https://github.com/ValveSoftware/source-sdk-2013/blob/master/mp/src/public/edict.h#L353-L356

Сообщения автоматически склеены: 23 Окт 2022

Описание самих флагов:

source-sdk-2013/edict.h at master · ValveSoftware/source-sdk-2013

The 2013 edition of the Source SDK. Contribute to ValveSoftware/source-sdk-2013 development by creating an account on GitHub.

github.com