TA TK уведомления админов

[HooLIGUN]

Раньше, в мани админ плагин вроде была встроена функция, при ТА (TeamAttack) и ТК(TeamKill) игрокам в чат были сообщения что Такой то игрок аттакует Напарника. Эти сообщения были независимо от команды, то есть например Террористы видели сообщения о ТА в команде Спецназа.
На сорсмоде видно только когда ТА происходит в своей команде.
Как сделать, чтобы админы видели ТА\ТК независимо от команды?

Полезно знать, когда нужно вычислить провокатора.

 

[AlmazON]

видели ТА\ТК независимо от команды

Спойлер: [Любая игра] Сообщения для других команд о TA/TK

#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("player_hurt", Event_TA_TK);
    HookEvent("player_death", Event_TA_TK);
}

public void Event_TA_TK(Event event, const char[] name, bool dontBroadcast)
{
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    if (attacker)
    {
        int victim = GetClientOfUserId(event.GetInt("userid")), teammate = GetClientTeam(victim);
        if (attacker != victim && GetClientTeam(attacker) == teammate)
        {
            for (int i = 1; i <= MaxClients; ++i)
            {
                if (IsClientInGame(i) && GetClientTeam(i) != teammate)
                    PrintToChat(i, "\x01Игрок \x03%N \x04%s \x01товарища по команде \x05%N", attacker, name[7] == 'h' ? "атакует":"убил", victim);
            }
        }
    }
}

 

[HooLIGUN]

Спойлер: [CS:GO] Сообщения для других команд о TA/TK

#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("player_hurt", Event_TA_TK);
    HookEvent("player_death", Event_TA_TK);
}

public void Event_TA_TK(Event event, const char[] name, bool dontBroadcast)
{
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    if (attacker)
    {
        int victim = GetClientOfUserId(event.GetInt("userid")), teammate = GetClientTeam(victim);
        if (GetClientTeam(attacker) == teammate)
        {
            for (int i = 1; i <= MaxClients; ++i)
            {
                if (IsClientInGame(i) && GetClientTeam(i) != teammate)
                    PrintToChat(i, "\x01Игрок \x03%N \x04%s \x01товарища по команде \x05%N", attacker, name[7] == 'h' ? "атакует":"убил", victim);
            }
        }
    }
}

Забыл указать, игра CS:S. Сработает ?

 

[AlmazON]

Сработает ?

Без разницы. Просто другой игре это может будет ни к чему, когда там итак всё всем пишет.

 

[HooLIGUN]

Без разницы. Просто другой игре это может будет ни к чему, когда там итак всё всем пишет.

Спасибо, а можно, чтобы это только для админов писало?

 

[HooLIGUN]

VIP'ам тоже оно надо или сразу конкретный админ-флаг имеется для этой цели?

Нет, только админам, флаг b например

 

[AlmazON]

админам, флаг b

Спойлер: [Любая игра] Сообщения админам других команд о TA/TK

#pragma newdecls required

bool IsAdmin_TA_TK[MAXPLAYERS + 1];

public void OnPluginStart()
{
    HookEvent("player_hurt", Event_TA_TK);
    HookEvent("player_death", Event_TA_TK);
}

public void OnClientPostAdminCheck(int client)
{
    IsAdmin_TA_TK[client] = GetAdminFlag(GetUserAdmin(client), Admin_Generic);
}

public void Event_TA_TK(Event event, const char[] name, bool dontBroadcast)
{
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    if (attacker)
    {
        int victim = GetClientOfUserId(event.GetInt("userid")), teammate = GetClientTeam(victim);
        if (attacker != victim && GetClientTeam(attacker) == teammate)
        {
            for (int i = 1; i <= MaxClients; ++i)
            {
                if (IsAdmin_TA_TK[i] && IsClientInGame(i) && GetClientTeam(i) != teammate)
                    PrintToChat(i, "\x01Игрок \x03%N \x04%s \x01товарища по команде \x05%N", attacker, name[7] == 'h' ? "атаковал":"убил", victim);
            }
        }
    }
}

 

[HooLIGUN]

Спойлер: [Любая игра] Сообщения админам других команд о TA/TK

#pragma newdecls required

bool IsAdmin_TA_TK[MAXPLAYERS + 1];

public void OnPluginStart()
{
    HookEvent("player_hurt", Event_TA_TK);
    HookEvent("player_death", Event_TA_TK);
}

public void OnClientPostAdminCheck(int client)
{
    IsAdmin_TA_TK[client] = GetAdminFlag(GetUserAdmin(client), Admin_Generic);
}

public void Event_TA_TK(Event event, const char[] name, bool dontBroadcast)
{
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    if (attacker)
    {
        int victim = GetClientOfUserId(event.GetInt("userid")), teammate = GetClientTeam(victim);
        if (GetClientTeam(attacker) == teammate)
        {
            for (int i = 1; i <= MaxClients; ++i)
            {
                if (IsAdmin_TA_TK[i] && IsClientInGame(i) && GetClientTeam(i) != teammate)
                    PrintToChat(i, "\x01Игрок \x03%N \x04%s \x01товарища по команде \x05%N", attacker, name[7] == 'h' ? "атаковал":"убил", victim);
            }
        }
    }
}

А как исключить суициды не подскажешь?

 

[HooLIGUN]

@AlmazON, Привет, а можешь добавить в плагин, чтобы показывалось, сколько хп сняли при атаке
Например
Игрок ... атакавал товарища по команде ... (-19hp)

 

[AlmazON]

в плагин

Оффтоп

Сейчас кину кости и узнаю, какой плагин имеется ввиду.

-19hp

Спама мало в чате? Тогда придётся делить общий код на 2 части.

 

[HooLIGUN]

Сейчас кину кости и узнаю, какой плагин имеется ввиду.

В смысле? Я же процитировал тебя конкретной теме, где постом выше есть твой код. Какие кости то??

Спама мало в чате? Тогда придётся делить общий код на 2 части.

Спама нет.
Ладно, я тебя понял.

 

[AlmazON]

выше есть твой код

Стоит всегда указывать, какой конкретно код. Зачастую, вы его вообще сами изменяете - обязательно прилагать свой.

Спойлер: [Любая игра] Сообщения админам других команд о TA/TK v2

#pragma newdecls required

bool IsAdmin_TA_TK[MAXPLAYERS + 1];

public void OnPluginStart()
{
    HookEvent("player_hurt", Event_TA_TK);
    HookEvent("player_death", Event_TA_TK);
}

public void OnClientPostAdminCheck(int client)
{
    IsAdmin_TA_TK[client] = GetAdminFlag(GetUserAdmin(client), Admin_Generic);
}

public void Event_TA_TK(Event event, const char[] name, bool dontBroadcast)
{
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    if (attacker)
    {
        int victim = GetClientOfUserId(event.GetInt("userid"));
        if (attacker != victim)
        {
            int teammate = GetClientTeam(victim);
            if (GetClientTeam(attacker) == teammate)
            {
                int i = MaxClients;
                if (name[7] == 'h')
                {
                    int damage = event.GetInt("dmg_health");
                    while (0 < i)
                    {
                        if (IsAdmin_TA_TK[i] && IsClientInGame(i) && GetClientTeam(i) != teammate)
                            PrintToChat(i, "\x01Игрок \x03%N \x04атаковал \x01товарища по команде \x05%N \x01(-%i)", attacker, victim, damage);
                        --i;
                    }
                }
                else
                {
                    while (0 < i)
                    {
                        if (IsAdmin_TA_TK[i] && IsClientInGame(i) && GetClientTeam(i) != teammate)
                            PrintToChat(i, "\x01Игрок \x03%N \x04убил \x01товарища по команде \x05%N", attacker, victim);
                        --i;
                    }
                }
            }
        }
    }
}