Можно ли полностью убрать кровь на стороне сервера

[meladzevalerii]

Добрый день.

Можно ли полностью убрать кровь на стенах со стороны сервера в CSGO, чтобы у всех зашедших ее не было по умолчанию?

Плагином или командами, не играет роли.

 

[DarklSide]

meladzevalerii,
Варианты:
a. Изменение mp_decals (r_decals/r_decalstaticprops/r_decal_cullsize) - у клиента.

b. Удаление env_blood -

public OnEntityCreated(entity, const String:classname[])
{
    decl bool:blood;
    blood = StrContains(classname, "env_blood", false) != -1 ? true:false;
    if(blood) RemoveEdict(entity);
}

c. Имитация -

public OnClientPutInServer(client)
{
    SDKHook(client, SDKHook_TraceAttack, Hook_TraceAttack);
}
public Action:Hook_TraceAttack(client, &attacker, &inflictor, &Float:damage, &damagetype, &ammotype, hitbox, hitgroup)
{
    if(IsValidEntity(client))
    {
        new healthblood = GetClientHealth(client) - RoundToNearest(damage);
        SetEntityHealth(client, healthblood);
        return Plugin_Handled;
    }
    return Plugin_Continue;
}

 

[meladzevalerii]

DarklSide

а в чем разница для конечного игрока между б и в

 

[dp909]

И все же на стороне сервера можно как то кровь убрать, есть предположения?

 

[White Wolf]

dp909, а почитать выше не?

 

[dp909]

White Wolf, читал и пробовал. В вариант у меня не работает, С работает, крови нет но игроки становятся не убиваемые..

 

[DarklSide]

dp909, попробуй заменить

return Plugin_Handled;

на

return Plugin_Changed;

Сама имитация - в блокировнии дамага из вне, считать этот дамаг, и отнимать из hp.

Получаем что крови нет, так как нет самого повреждения (выстрела).

 

[dp909]

DarklSide, Теперь кровь появилась но режим "бога" остался.. под 65 000 hp у игрока.

Добавлено через 22 часа 5 минут

 

[DarklSide]

dp909, обширно

Спойлер

#pragma semicolon 1
#include <sourcemod>
#include <sdktools_tempents>
static const String:bloods[][] = 
{
    "Blood Stream",
    "Blood Sprite",
    "EffectDispatch", 
    "World Decal"
};
public OnPluginStart()
{
    for (new i = 0; i < sizeof(bloods); i++)
    {
        AddTempEntHook(bloods[i], Hook_bloods);
    }
}
public Action:Hook_bloods(const String:te_name[], const Players[], numClients, Float:delay)
{
    return Plugin_Stop;
}

 

[CaJI9pA]

Может вопрос туповат, а куда все это прописывать?

 

[Drumanid]

#include <cstrike>
#include <sourcemod>
#include <sdkhooks>
#include <smlib>

//Compiler Options
#pragma semicolon 1
#pragma newdecls required

ConVar g_cEnableNoBlood;
ConVar g_cEnableNoBloodSplatter;
ConVar g_cEnableNoBloodSplash;

public Plugin myinfo =
{
    name = "DisableBlood",
    author = "shanapu,bara",
    description = "Disable Blood on your server - all credits to bara",
    version = "1.0",
    url = "shanapu.de"
};

public void OnPluginStart()
{
    g_cEnableNoBlood = CreateConVar("sm_blood_disable", "0", "Enable / Disable No Blood", _, true, 0.0, true, 1.0);
    g_cEnableNoBloodSplatter = CreateConVar("sm_blood_disable_splatter", "0", "Enable / Disable No Blood Splatter", _, true, 0.0, true, 1.0);
    g_cEnableNoBloodSplash = CreateConVar("sm_blood_disable_splash", "0", "Enable / Disable No Blood Splash", _, true, 0.0, true, 1.0);

    AddTempEntHook("EffectDispatch", TE_OnEffectDispatch);
    AddTempEntHook("World Decal", TE_OnWorldDecal);
}

public Action TE_OnEffectDispatch(const char[] te_name, const Players[], int numClients, float delay)
{
    int iEffectIndex = TE_ReadNum("m_iEffectName");
    int nHitBox = TE_ReadNum("m_nHitBox");
    char sEffectName[64];
   
    GetEffectName(iEffectIndex, sEffectName, sizeof(sEffectName));
   
    if(g_cEnableNoBlood.BoolValue)
    {
        if(StrEqual(sEffectName, "csblood"))
        {
            if(g_cEnableNoBloodSplatter.BoolValue)
                return Plugin_Handled;
        }
        if(StrEqual(sEffectName, "ParticleEffect"))
        {
            if(g_cEnableNoBloodSplash.BoolValue)
            {
                char sParticleEffectName[64];
                GetParticleEffectName(nHitBox, sParticleEffectName, sizeof(sParticleEffectName));
               
                if(StrEqual(sParticleEffectName, "impact_helmet_headshot") || StrEqual(sParticleEffectName, "impact_physics_dust"))
                    return Plugin_Handled;
            }
        }
    }
    return Plugin_Continue;
}

public Action TE_OnWorldDecal(const char[] te_name, const Players[], int numClients, float delay)
{
    float vecOrigin[3];
    int nIndex = TE_ReadNum("m_nIndex");
    char sDecalName[64];
   
    TE_ReadVector("m_vecOrigin", vecOrigin);
    GetDecalName(nIndex, sDecalName, sizeof(sDecalName));
   
    if(g_cEnableNoBlood.BoolValue)
    {
        if(StrContains(sDecalName, "decals/blood") == 0 && StrContains(sDecalName, "_subrect") != -1)
            if(g_cEnableNoBloodSplash.BoolValue)
                return Plugin_Handled;
    }
    return Plugin_Continue;
}

stock int GetParticleEffectName(int index, char[] sEffectName, int maxlen)
{
    int table = INVALID_STRING_TABLE;
   
    if (table == INVALID_STRING_TABLE)
        table = FindStringTable("ParticleEffectNames");
   
    return ReadStringTable(table, index, sEffectName, maxlen);
}

stock int GetEffectName(int index, char[] sEffectName, int maxlen)
{
    int table = INVALID_STRING_TABLE;
   
    if (table == INVALID_STRING_TABLE)
        table = FindStringTable("EffectDispatch");
   
    return ReadStringTable(table, index, sEffectName, maxlen);
}

stock int GetDecalName(int index, char[] sDecalName, int maxlen)
{
    int table = INVALID_STRING_TABLE;
   
    if (table == INVALID_STRING_TABLE)
        table = FindStringTable("decalprecache");
   
    return ReadStringTable(table, index, sDecalName, maxlen);
}

Это на всякий, если верхний вариант работать не будет.

 

[CaJI9pA]

Всё прекрасно заработало) fps даже поднялся. Спасибо за предложения!

 

[Yura7181]

dp909, обширно

Спойлер

#pragma semicolon 1
#include <sourcemod>
#include <sdktools_tempents>
static const String:bloods[][] =
{
    "Blood Stream",
    "Blood Sprite",
    "EffectDispatch",
    "World Decal"
};
public OnPluginStart()
{
    for (new i = 0; i < sizeof(bloods); i++)
    {
        AddTempEntHook(bloods[i], Hook_bloods);
    }
}
public Action:Hook_bloods(const String:te_name[], const Players[], numClients, Float:delay)
{
    return Plugin_Stop;
}

Здорово помог снизить лаги и поднять фпс. Большое спасибо!

 

[SlavON]

@Drumanid, чудо какое-то, сначала всё работало, потом перестало :blink:
--- Добавлено позже ---
@DarklSide, а в твоей версии не видно взрыва от HE гранат))

 

[Drumanid]

@Drumanid, чудо какое-то, сначала всё работало, потом перестало :blink:

Спойлер: Ответ

 

[Lima]

@Tony, попробуй этот:

#include <sdktools>

public void OnPluginStart()
{
    AddTempEntHook("World Decal", OnWorldDecal);
}

public Action OnWorldDecal(const char[] te_name, const Players[], int numClients, float delay)
{
    float vecOrigin[3];
    int nIndex = TE_ReadNum("m_nIndex");
    char sDecalName[64];

    TE_ReadVector("m_vecOrigin", vecOrigin);
    GetDecalName(nIndex, sDecalName, sizeof(sDecalName));
   
    if(StrContains(sDecalName, "decals/blood") == 0 && StrContains(sDecalName, "_subrect") != -1)
    {
        return Plugin_Handled;
    }

    return Plugin_Continue;
}

stock int GetDecalName(int index, char[] sDecalName, int maxlen)
{
    int table = INVALID_STRING_TABLE;
   
    if (table == INVALID_STRING_TABLE)
        table = FindStringTable("decalprecache");
   
    return ReadStringTable(table, index, sDecalName, maxlen);
}

 

[Lima]

во спреи работают, кровь хлещет, но на полу и стенах не остается

Ну хоть как-то)

 

[xek]

@Tony, попробуй этот:

#include <sdktools>

public void OnPluginStart()
{
    AddTempEntHook("World Decal", OnWorldDecal);
}

public Action OnWorldDecal(const char[] te_name, const Players[], int numClients, float delay)
{
    float vecOrigin[3];
    int nIndex = TE_ReadNum("m_nIndex");
    char sDecalName[64];

    TE_ReadVector("m_vecOrigin", vecOrigin);
    GetDecalName(nIndex, sDecalName, sizeof(sDecalName));
  
    if(StrContains(sDecalName, "decals/blood") == 0 && StrContains(sDecalName, "_subrect") != -1)
    {
        return Plugin_Handled;
    }

    return Plugin_Continue;
}

stock int GetDecalName(int index, char[] sDecalName, int maxlen)
{
    int table = INVALID_STRING_TABLE;
  
    if (table == INVALID_STRING_TABLE)
        table = FindStringTable("decalprecache");
  
    return ReadStringTable(table, index, sDecalName, maxlen);
}

Всё ок, только на дверях (csgo - dust2) есть кровь

 

[EaglEs]

Ну это модели, а не браши...

 

[Phrog]

На новом dust2 ни один из способов не работает.