Написание плагинов

[R1KO]

@Крутой),

new Handle:hTopMenu;

 

[Karmushka]

@Крутой),

new Handle:hTopMenu;

что это???

 

[R1KO]

@Крутой), добавь после инклюдов

 

[Karmushka]

@Крутой), добавь после инклюдов

С happy получилось, но с teleport не получилось ошибка!

 

[Almaz2512]

Здравствуйте, нужно сделать квар для отключения и включения плагина на определенной карте.
[ANY] Force Landmark Angles - AlliedModders

 

[Tonki_Ton]

Здравствуйте, нужно сделать квар для отключения и включения плагина на определенной карте.
[ANY] Force Landmark Angles - AlliedModders

Map configs with prefix support 1.3 - AlliedModders

 

[Almaz2512]

Map configs with prefix support 1.3 - AlliedModders

Юзал, пробовал прописать через "sm plugins load (unload)" индивидуально на каждой карте, но все сбрасывается.
Если бы все было так просто, не стал бы сюда писать)

 

[Grey83]

Держи, добавил квар landmarkangles_enable на включение/отключение.
Дефолтом стоит 0
Просто в Map configs with prefix support пропиши включение только на тех картах, на которых тебе нужно, чтобы плагин работал.

 

[Almaz2512]

Очень странно, но значения не меняются без перезапуска сервера.

 

[Grey83]

@Almaz2512, где не меняются?

 

[Tonki_Ton]

Юзал, пробовал прописать через "sm plugins load (unload)" индивидуально на каждой карте, но все сбрасывается.
Если бы все было так просто, не стал бы сюда писать)

Все именно так просто как кажется, добавляешь анлоад в сервер кфг и подгружаешь на нужных картах.
Или тебе не это нужно ?

 

[AlmazON]

значения не меняются без перезапуска сервера

30 строку:

public void OnMapStart()

Замени на:

public void OnConfigsExecuted()

Оффтоп

А вообще, квар добавлен несколько грубо.

 

[Napas]

Добрый вечер, можно заблочить команду status на уровне клиента? Если да прошу написать данный плагин.

 

[AlmazON]

заблочить команду status на уровне клиента

В CS:GO только на всех "уровнях" - и клиент, и сервер.

 

[Napas]

В CS:GO только на всех "уровнях" - и клиент, и сервер.

Плохо (

 

[Almaz2512]

@Almaz2512, где не меняются?

Точнее значение "landmarkangles_enable" меняется, но при изменении значения на 1 ничего не происходит, т.е плагин не запускается.

30 строку:

public void OnMapStart()

Замени на:

public void OnConfigsExecuted()

Оффтоп

А вообще, квар добавлен несколько грубо.

Опять не помогло(

 

[AlmazON]

не помогло

Спойлер: Force Landmark Angles v1.1.1cvar

#include <sdkhooks>
#include <sdktools>

#pragma newdecls required

Handle g_hDestinationLookup;
float g_vecPlayerRotations[MAXPLAYERS+1][3];

bool bEnable;

public Plugin myinfo =
{
	name		= "Force Landmark Angles",
	author		= "Neuro Toxin",
	description	= "Forces trigger teleports to use Landmark Angles",
	version		= "1.1.1cvar",
}

public void OnPluginStart()
{
	ConVar hEnable = CreateConVar("landmarkangles_enable", "0", "Enables/disables the plugin.", _, true, 0.0, true, 1.0);
	bEnable	= hEnable.BoolValue;
	hEnable.AddChangeHook(OnCVarChanged);
	g_hDestinationLookup = CreateTrie();
}

public void OnCVarChanged(ConVar convar, const char[] oldValue, const char[] newValue)
{
	if ((bEnable = convar.BoolValue)) OnConfigsExecuted();
	else ClearTrie(g_hDestinationLookup);
}

public void OnConfigsExecuted()
{
	if (bEnable)
	{
		ClearTrie(g_hDestinationLookup);

		// Late load
		int entity = MaxClients + 1;
		while ((entity = FindEntityByClassname(entity, "trigger_teleport")) != -1)
		{
			OnEntitySpawned(entity);
		}
	}
}

public void OnEntityCreated(int entity, const char[] classname)
{
	if (!bEnable || strcmp(classname, "trigger_teleport")) return;

	SDKHook(entity, SDKHook_SpawnPost, OnEntitySpawned);
}

public void OnEntitySpawned(int entity)
{
	SDKUnhook(entity, SDKHook_SpawnPost, OnEntitySpawned);

	SetEntProp(entity, Prop_Data, "m_bUseLandmarkAngles", 0);
	if (SetTeleportTarget(entity))
	{
		HookSingleEntityOutput(entity, "OnStartTouch", OnEntityStartTouch);
		HookSingleEntityOutput(entity, "OnEndTouch", OnEntityEndTouch);
	}
}

public void OnEntityStartTouch(const char[] output, int caller, int activator, float delay)
{
	int target = GetTeleportTarget(caller);
	if (target == -1) return;

	float m_vecOrigin[3]; float m_angRotation_player[3]; float m_angRotation[3]; float m_vecAbsVelocity[3];
	GetEntPropVector(target, Prop_Send, "m_vecOrigin", m_vecOrigin);
	GetEntPropVector(activator, Prop_Data, "m_angRotation", m_angRotation_player);
	GetEntPropVector(target, Prop_Data, "m_angRotation", m_angRotation);
	GetEntPropVector(activator, Prop_Data, "m_vecAbsVelocity", m_vecAbsVelocity);

	m_vecAbsVelocity[2] = 0.0; // remove fall speed

	float speed = GetVectorLength(m_vecAbsVelocity);
	float fwvec[3];
	GetAngleVectors(m_angRotation, fwvec, NULL_VECTOR, NULL_VECTOR);
	NormalizeVector(fwvec, fwvec);
	ScaleVector(fwvec, speed);

	g_vecPlayerRotations[activator] = m_angRotation;
	g_vecPlayerRotations[activator][0] = m_angRotation_player[0];

	//fwvec[2] = 0.0; // remove fall speed
	TeleportEntity(activator, m_vecOrigin, g_vecPlayerRotations[activator], fwvec);
}

public void OnEntityEndTouch(const char[] output, int caller, int activator, float delay)
{
	TeleportEntity(activator, NULL_VECTOR, g_vecPlayerRotations[activator], NULL_VECTOR);
}

stock bool SetTeleportTarget(int trigger_teleport)
{
	char m_target[128];
	GetEntPropString(trigger_teleport, Prop_Data, "m_target", m_target, sizeof(m_target))

	int target = FindTeleportTarget(m_target);
	if (target == -1)
		return false;

	SetTrieValue(g_hDestinationLookup, m_target, target);
	return true;
}

stock int FindTeleportTarget(const char[] targetname)
{
	char buffer[128];
	int entity = -1;
	while ((entity = FindEntityByClassname(entity, "info_teleport_destination")) > -1)
	{
		GetEntPropString(entity, Prop_Data, "m_iName", buffer, sizeof(buffer));
		if (StrEqual(targetname, buffer)) return entity;
	}

	return -1;
}

stock int GetTeleportTarget(int trigger_teleport)
{
	char m_target[128];
	GetEntPropString(trigger_teleport, Prop_Data, "m_target", m_target, sizeof(m_target))

	int target;
	if (GetTrieValue(g_hDestinationLookup, m_target, target)) return target;

	return -1;
}

 

[Grey83]

@AlmazON, Оффтоп

хм, и для конваров методмап есть?
Надо же. Не знал.
И при объявлении конвара в OnPluginStart() он всё равно будет глобальным для плагина?
А то я по старинке делаю это в заголовке плагинов.

 

[AlmazON]

при объявлении конвара в OnPluginStart() он всё равно будет глобальным для плагина?

Оффтоп

Что-то не совсем понял тебя.
А так да, полно methodmap'ов для квара - почти на всё, если не всё. Просто всегда открываем вкладку "File" для любой библиотеки, чуть дальше констант они расписаны.

 

[Almaz2512]

@Grey83, @AlmazON, Квар так и толком не заработал, зато заработала команда sm plugins load, за что большое спасибо)
По возможности, не могли бы вы проделать тоже самое с этим

Спойлер

#include <sdkhooks>

public Plugin myinfo =
{
name = "Force Landmark Angles",
author = "Neuro Toxin",
description = "Forces trigger teleports to use Landmark Angles",
version = "1.0.0",
}

public void OnEntityCreated(int entity, const char[] classname)
{
if (!StrEqual(classname, "trigger_teleport"))
return;

SDKHook(entity, SDKHook_Spawn, OnEntitySpawned);
}

public OnEntitySpawned(entity)
{
SDKUnhook(entity, SDKHook_Spawn, OnEntitySpawned);
SetEntProp(entity, Prop_Data, "m_bUseLandmarkAngles", 1);
}

Еще раз благодарю)