Неконтролируемый рост entities

Paranoiiik

Paranoiiik

хачю клиентмод
Сообщения
2,047
Реакции
1,490
После старта карты некоторое время количество оружия стоит на отметке 60-70. Через какое-то время число у каждого резко возрастает и продолжает расти:
report_entities: 
Class: weapon_awp (397)
Class: weapon_deagle (397)
Class: weapon_knife (398)
Как следствие - краш (ED_Alloc: no free edicts)

Может ли такой эффект давать этот код?
C-подобный: 
#pragma semicolon 1
#pragma newdecls required

#include sdktools

public Plugin myinfo    =
{
    name                = "Del Deagle on awp_ maps",
    author                = "GoTT && Paranoiiik",
    version                = "1.1",
    url                    = "hlmod.ru/resources/no-deagle-on-awp-maps.858 / vk.com/oldfreelance"
};

public void OnPluginStart()
{
    HookEvent("player_spawn", eventPlayerSpawn);
}

public Action eventPlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
    char szMap[128];
    GetCurrentMap(szMap, sizeof szMap);
   
    if(szMap[0] == 'a' && szMap[1] == 'w' && szMap[2] == 'p' && szMap[3] == '_')
    {
        int client = GetClientOfUserId(event.GetInt("userid"));

        if(IsPlayerAlive(client))
        {
            int iItems;
            for(int i = 0; i < 6; i++) if(i < 6 && (iItems = GetPlayerWeaponSlot(client, i)) != -1) RemovePlayerItem(client, iItems);
           
            GivePlayerItem(client, "weapon_knife");
            GivePlayerItem(client, "weapon_awp");
        }
    }
}
Подозреваю, что в нём дело и есть, но не знаю, как побороть это ввиду отсутствия должных знаний и опыта.
На этой карте, если что, работает DM. Краши строго на этой карте строго по такому сценарию. Один и тот же краш.

SM 1.10, CS:S v34
 
Решение
Paranoiiik
Grey83 написал(а):
исправил
код обновил
Нажмите, чтобы раскрыть...
Удаляет всё оружие вообще и не выдаёт

Удалось добиться, в общем, желаемого результата так:
C-подобный: 
#pragma semicolon 1
#pragma newdecls required

#include sdktools_functions
#include sdktools_entinput

public Plugin myinfo    =
{
    name                = "Delete Deagle on AWP maps",
    author                = "Grey83",
    version                = "1.0",
    url                    = "hlmod.ru/threads/nekontroliruemyj-rost-entities.59625"
};

public void OnMapStart()
{
    static bool bHooked;
    char sMap[128];
   
    GetCurrentMap(sMap, sizeof sMap);
    GetMapDisplayName(sMap, sMap, sizeof sMap);
   
    if((!strncmp(sMap, "awp_", 4, false)) == bHooked) return;

    if(!(bHooked = !bHooked))...
Сортировать по дате Сортировать по голосам
K

Kotya

Участник
Сообщения
15
Реакции
9
На сервере есть плагин, который чистит оружие на полу после смерти игрока?
 
За 0 Против
Paranoiiik

Paranoiiik

хачю клиентмод
Сообщения
2,047
Реакции
1,490
Kotya написал(а):
На сервере есть плагин, который чистит оружие на полу после смерти игрока?
Нажмите, чтобы раскрыть...
Да
Сообщения автоматически склеены:

Вот этим чищу:
C-подобный: 
#pragma semicolon 1
#pragma newdecls required

int iWeaponParent;

public Plugin myinfo    =
{
    name                = "SM Weapon Cleanup [Light + New Syntax]",
    author                = "TechKnow",
    description            = "Removes loose weapons droped",
    version                = "1.3.1",
    url                    = "http://www.sourcemod.net"
};

public void OnPluginStart()
{
    iWeaponParent = FindSendPropInfo("CBaseCombatWeapon", "m_hOwnerEntity");
    
    HookEvent("player_death", eventCleanUp, EventHookMode_Post);
    HookEvent("round_start", eventCleanUp, EventHookMode_Post);
}

Action eventCleanUp(Event event, const char[] name, bool dontBroadcast)
{
    int        iMaxEntities = GetMaxEntities();
    char    sWeapon[64];
    
    for(int i = MaxClients; i < iMaxEntities; i++)
    {
        if(IsValidEdict(i) && IsValidEntity(i))
        {
            GetEdictClassname(i, sWeapon, sizeof sWeapon);
            if((StrContains(sWeapon,  "weapon_") != -1 || StrContains(sWeapon, "item_") != -1) && GetEntDataEnt2(i, iWeaponParent) == -1) RemoveEdict(i);
        }
    }
    
    return Plugin_Continue;
}
 
За 0 Против
K

Kotya

Участник
Сообщения
15
Реакции
9
Оружие чиститься когда кто-то умирает, плагином выше вы, когда игрок спавнится, забираете все оружие и выдаете только нож и авп, на логах видно, что там есть еще диглы, как могут диглы появится в теории(может есть какая-то не учтенная возможность получения оружия)?
 
За 0 Против
Paranoiiik

Paranoiiik

хачю клиентмод
Сообщения
2,047
Реакции
1,490
Kotya написал(а):
Оружие чиститься когда кто-то умирает, плагином выше вы, когда игрок спавнится, забираете все оружие и выдаете только нож и авп, на логах видно, что там есть еще диглы, как могут диглы появится в теории(может есть какая-то не учтенная возможность получения оружия)?
Нажмите, чтобы раскрыть...
Оружие выдаёт лишь сама карта: авп, дигл и нож. Плагином стараюсь избавиться от дигла. Никакие другие плагины не выдают оружие ни при каких обстоятельствах
 
За 0 Против
K

Kotya

Участник
Сообщения
15
Реакции
9
В теории, если игроки не будут убивать друг-друга и оружие будет постоянно спавнится, то может случится краш
 
За 0 Против
Paranoiiik

Paranoiiik

хачю клиентмод
Сообщения
2,047
Реакции
1,490
Kotya написал(а):
В теории, если игроки не будут убивать друг-друга и оружие будет постоянно спавнится, то может случится краш
Нажмите, чтобы раскрыть...
Представляю, как на DM игроки просто стоят и смотрят друг на друга.
Нет, там мясо, постоянно кто-то кого-то убивает.
 
За 0 Против
M

Madness aka null138

Участник
Сообщения
713
Реакции
734
Потому что удаляется неправильным образом. В итоге накапливается раунд за раундом. Не дочитал до части с DM. но суть та же, при каждом спавне создается новая а старая остается.

RemovePlayerItem удаляет у игрока, но само энтити остается. Надо еще добавить AcceptEntityInput(entity, "kill");
 
За 1 Против
Paranoiiik

Paranoiiik

хачю клиентмод
Сообщения
2,047
Реакции
1,490
Madness aka null138 написал(а):
Потому что удаляется неправильным образом. В итоге накапливается раунд за раундом. Не дочитал до части с DM. но суть та же, при каждом спавне создается новая а старая остается.

RemovePlayerItem удаляет у игрока, но само энтити остается. Надо еще добавить AcceptEntityInput(entity, "kill");
Нажмите, чтобы раскрыть...
То есть как-то так?
C-подобный: 
#pragma semicolon 1
#pragma newdecls required

#include sdktools

public Plugin myinfo    =
{
    name                = "Del Deagle on awp_ maps",
    author                = "GoTT && Paranoiiik",
    version                = "1.1",
    url                    = "hlmod.ru/resources/no-deagle-on-awp-maps.858 / vk.com/oldfreelance"
};

public void OnPluginStart()
{
    HookEvent("player_spawn", eventPlayerSpawn);
}

public Action eventPlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
    char szMap[128];
    GetCurrentMap(szMap, sizeof szMap);
    
    if(szMap[0] == 'a' && szMap[1] == 'w' && szMap[2] == 'p' && szMap[3] == '_')
    {
        int client = GetClientOfUserId(event.GetInt("userid"));

        if(IsPlayerAlive(client))
        {
            int iItems;
            
            for(int i = 0; i < 6; i++)
            {
                if(i < 6 && (iItems = GetPlayerWeaponSlot(client, i)) != -1)
                {
                    RemovePlayerItem(client, iItems);
                    
                    int iEntity = -1;
                    
                    if((iEntity = FindEntityByClassname(iEntity, "weapon_knife")) > 0
                    || (iEntity = FindEntityByClassname(iEntity, "weapon_deagle")) > 0
                    || (iEntity = FindEntityByClassname(iEntity, "weapon_awp")) > 0)
                        AcceptEntityInput(iEntity, "kill");
                }
            }
            
            GivePlayerItem(client, "weapon_knife");
            GivePlayerItem(client, "weapon_awp");
        }
    }
}
Сообщения автоматически склеены:

Нет, ничего не работает. Перепробовал кучу способов. С какими-то рост всё равно продолжается и ещё нож.. почему-то удаляется рандомно, с какими-то удаляется всё оружие из рук живых игроков.
Может, кто-то знает, как сделать так, чтобы удалить нахрен всё, но не трогать оружие, которое в руках.. было бы классно
Сообщения автоматически склеены:

Если что, Weapon Restrict почему-то выставляет значение на 0, но оружие не отбирает всё равно, потому его не использую
 
Последнее редактирование:
За 0 Против
Rolzzandik

Rolzzandik

Участник
Сообщения
492
Реакции
234
C-подобный: 
RemovePlayerItem(iClient, iEnt);
AcceptEntityInput(iEnt, "KillHierarchy");

И вот этот ужас
Paranoiiik написал(а):
for(int i = 0; i < 6; i++) if(i < 6 && (iItems = GetPlayerWeaponSlot(client, i)) != -1)
Нажмите, чтобы раскрыть...
правильней заменить на
C-подобный: 
int iSize = GetEntPropArraySize(iClient, Prop_Send, "m_hMyWeapons");
for (int i = 0; i < iSize; i++){
int iEnt = GetEntPropEnt(iClient, Prop_Send, "m_hMyWeapons", i);
//Код где работаем с iEnt - наша пушка)

Ну если прям так хочется сделать говнокод(я про себя), то попробуй так:
дааа: 
int iSize = GetEntPropArraySize(iClient, Prop_Send, "m_hMyWeapons");
for (int i = 0; i < iSize; i++){
    int iEnt = GetEntPropEnt(iClient, Prop_Send, "m_hMyWeapons", i);
    if(iEnt == -1)
        return; //Тут стоит учитывать, что если  используешь хук, то тут Plugin_continue
    char szTemp[32];
    GetEntityClassname(iEnt, szTemp, sizeof szTemp);
    if(StrContains(szTemp, "deagle", false) != -1) {
        RemovePlayerItem(iClient, iEnt);
        AcceptEntityInput(iEnt, "KillHierarchy");
    }
Paranoiiik написал(а):
но не трогать оружие, которое в руках
Нажмите, чтобы раскрыть...
Работать с
int iActive = GetEntPropEnt(iClient, Prop_Send, "m_hActiveWeapon"); - Это то оружие, которое у нас непосредственно в руках
 
Последнее редактирование:
За 1 Против
Deluks

Deluks

Верховное DNO|
Сообщения
1,853
Реакции
812
Paranoiiik написал(а):
После старта карты некоторое время количество оружия стоит на отметке 60-70. Через какое-то время число у каждого резко возрастает и продолжает расти:

Как следствие - краш (ED_Alloc: no free edicts)
Нажмите, чтобы раскрыть...

У меня на го такая выскакивала. запретил просто оружке выпадать с рук, все норм.

Может и тебе так селать?
 
За 0 Против
Grey83

Grey83

не пишу плагины с весны 2022
Сообщения
8,521
Реакции
4,980
@Deluks, а такой квар в этом говне мамонта, CSS v34, имеется?
Сообщения автоматически склеены:

@Paranoiiik,попробуй так:
C-подобный: 
#pragma semicolon 1
#pragma newdecls required

#include <sdktools_functions>
#include <sdktools_entinput>

bool bAWP;

public void OnMapStart()
{
    static bool hooked;
    char map[128];
    GetCurrentMap(map, sizeof(map));
    GetMapDisplayName(map, map, sizeof(map));
    if((bAWP = !strncmp(map, "awp_", 4, false)) == hooked) return;

    if(!(hooked = !hooked))
        UnhookEvent("player_spawn", Event_Spawn);
    else HookEvent("player_spawn", Event_Spawn);
}

public void Event_Spawn(Event event, const char[] name, bool dontBroadcast)
{
    static int client;
    if(!(client = GetClientOfUserId(event.GetInt("userid")))) return;

    RemoveWeaponBySlot(client, 0);
    RemoveWeaponBySlot(client, 1);
    while(RemoveWeaponBySlot(client, 3)) {}
    GivePlayerItem(client, "weapon_awp");
}

stock bool RemoveWeaponBySlot(int client, int slot)
{
    int ent = GetPlayerWeaponSlot(client, slot);
    return ent > MaxClients && RemovePlayerItem(client, ent) && AcceptEntityInput(ent, "Kill");
}

public void OnEntityCreated(int entity, const char[] classname)
{
    if(bAWP && entity > MaxClients && !strncmp(classname, "weapon_", 7, false)
    && (strcmp(classname[7], "awp", false) || strcmp(classname[7], "knife", false)))
        AcceptEntityInput(entity, "Kill");
}
При спавне у игрока будет отбираться всё оружие, кроме ножа и будет выдана AWP. Также с карты будет удаляться всё вновь созданное оружие, кроме ножей и AWP.
Сообщения автоматически склеены:

Скрипт совместим с мастерской (так что должен работать на CS:S OB и CS:GO).
 
Последнее редактирование:
За 1 Против
Paranoiiik

Paranoiiik

хачю клиентмод
Сообщения
2,047
Реакции
1,490
Grey83 написал(а):
@Deluks, а такой квар в этом говне мамонта, CSS v34, имеется?
Сообщения автоматически склеены:

@Paranoiiik,попробуй так:
C-подобный: 
#pragma semicolon 1
#pragma newdecls required

#include <sdktools_functions>
#include <sdktools_entinput>

bool bAWP;

public void OnMapStart()
{
    static bool hooked;
    char map[128];
    GetCurrentMap(map, sizeof(map));
    GetMapDisplayName(map, map, sizeof(map));
    if((bAWP = !strncmp(map, "awp_", 4, false)) == hooked) return;

    if(!(hooked = !hooked))
        UnhookEvent("player_spawn", Event_Spawn);
    else HookEvent("player_spawn", Event_Spawn);
}

public void Event_Spawn(Event event, const char[] name, bool dontBroadcast)
{
    static int client;
    if(!(client = GetClientOfUserId(event.GetInt("userid")))) return;

    RemoveWeaponBySlot(client, 0);
    RemoveWeaponBySlot(client, 1);
    while(RemoveWeaponBySlot(client, 3)) {}
    GivePlayerItem(client, "weapon_awp");
}

stock bool RemoveWeaponBySlot(int client, int slot)
{
    int ent = GetPlayerWeaponSlot(client, slot);
    return ent > MaxClients && RemovePlayerItem(client, ent) && AcceptEntityInput(ent, "Kill");
}

public void OnEntityCreated(int entity, const char[] classname)
{
    if(bAWP && entity > MaxClients && !strncmp(classname, "weapon_", 7, false) && strcmp(classname[7], "awp", false))
        AcceptEntityInput(entity, "Kill");
}
При спавне у игрока будет отбираться всё оружие, кроме ножа и будет выдана AWP. Также с карты будет удаляться всё вновь созданное оружие, кроме ножей и AWP.
Сообщения автоматически склеены:

Скрипт совместим с мастерской (так что должен работать на CS:S OB и CS:GO).
Нажмите, чтобы раскрыть...
Удаляет нож
 
За 0 Против
Paranoiiik

Paranoiiik

хачю клиентмод
Сообщения
2,047
Реакции
1,490
Grey83 написал(а):
исправил
код обновил
Нажмите, чтобы раскрыть...
Удаляет всё оружие вообще и не выдаёт

Удалось добиться, в общем, желаемого результата так:
C-подобный: 
#pragma semicolon 1
#pragma newdecls required

#include sdktools_functions
#include sdktools_entinput

public Plugin myinfo    =
{
    name                = "Delete Deagle on AWP maps",
    author                = "Grey83",
    version                = "1.0",
    url                    = "hlmod.ru/threads/nekontroliruemyj-rost-entities.59625"
};

public void OnMapStart()
{
    static bool bHooked;
    char sMap[128];
   
    GetCurrentMap(sMap, sizeof sMap);
    GetMapDisplayName(sMap, sMap, sizeof sMap);
   
    if((!strncmp(sMap, "awp_", 4, false)) == bHooked) return;

    if(!(bHooked = !bHooked))    UnhookEvent("player_spawn",    eventPlayerSpawn);
    else                        HookEvent("player_spawn",    eventPlayerSpawn);
}

public void eventPlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
    static int client;
    if(!(client = GetClientOfUserId(event.GetInt("userid")))) return;

    RemoveWeaponBySlot(client, 0);
    RemoveWeaponBySlot(client, 1);
    RemoveWeaponBySlot(client, 2);
   
    GivePlayerItem(client, "weapon_knife");
    GivePlayerItem(client, "weapon_awp");
}

stock bool RemoveWeaponBySlot(int client, int slot)
{
    int iEntity = GetPlayerWeaponSlot(client, slot);
    return iEntity > MaxClients && RemovePlayerItem(client, iEntity) && AcceptEntityInput(iEntity, "Kill");
}
На всякий случай напишу, что проблема решена, если за ближайший день не увижу крашей. Я почти уверен, что их не будет, но хочу перестраховаться

UPD: Спасибо @Grey83!
 
Последнее редактирование:
За 0 Против
Решение
Paranoiiik

Paranoiiik

хачю клиентмод
Сообщения
2,047
Реакции
1,490
Grey83 написал(а):
@Paranoiiik, слот #2 - это нож, кстати
#3 - гранаты
Нажмите, чтобы раскрыть...
В том и суть, что лично мне гранаты не нужны в данном решении, д и не видел я lego-карт с гранатами вроде. Решил удалять всё оружие в общем и выдавать нужное
 
За 0 Против
Войдите или зарегистрируйтесь для ответа.

Похожие темы

I
Нужна помощь в устранении предупреждений (Warnings) в коде плагина.
Ответы
3
Просмотры
379
ilya85i
I
Фантэйззи
  • Вопрос
[PLUGIN] Warmup random weapon
Ответы
4
Просмотры
417
Grey83
Grey83
Besais
  • Вопрос
Нужна помощь с кодом
Ответы
15
Просмотры
871
Svyatoy
Svyatoy
N
  • Вопрос
Ошибка в плагине
Ответы
12
Просмотры
707
google>
G
KENEZEZ
  • Вопрос
CShowActivity2
Ответы
9
Просмотры
835
Grey83
Grey83
Сверху Снизу