[CS: GO] Плагин/скрипт на большое окно очков всегда.

[Dreizehnt]

Вообщем, существует ошибка, когда происходит смена сторон на сервере (mp_halftime 1), то рушится таблица очков ("scoreboard"), т.е. 5 игроков отображает, а остальные наплывают на само окно. Расширяется окно, когда много игроков на сервере и то не всегда. Возможно удастся создать плагин, который бы сообщал окну, что на сервере много игроков и давай расширяться, даже при нескольких, например.

 

[Drumanid]

Сделай обычный режим, но тогда и mp_halftime не будет работать...
Оффтоп

Может быть проще будет сделать смену команд на определенном раунде.

 

[Dreizehnt]

Сделай обычный режим, но тогда и mp_halftime не будет работать...
Оффтоп

Может быть проще будет сделать смену команд на определенном раунде.

Ставил обычный там тоже ломается... Вэлв же рассчитало так, что их сервера забиваются битком всегда, а на обычные сервера не подумали...

 

[Drumanid]

Ставил обычный там тоже ломается... Вэлв же рассчитало так, что их сервера забиваются битком всегда, а на обычные сервера не подумали...

Выключи mp_halftime и все будет нормально, сам с этим долго мучался.

 

[Dreizehnt]

Выключи mp_halftime и все будет нормально, сам с этим долго мучался.

Я то выключил, про это знаю, но смена сторон нужна вообще)
--- Добавлено позже ---
Может есть плагин на смену сторон, без "халфтайм"?

 

[666pro]

Поддерживаю , такая же проблема.

Выключи mp_halftime и все будет нормально, сам с этим долго мучался.

Нужна смена сторон как-бы.

 

[Danyas]

В чём проблема пройтись циклом по всем игрокам и просто изменить им команду в конце N-го раунда?
--- Добавлено позже ---

#include <cstrike>

public Plugin:myinfo =
{
    name = "HalfTime Replacer",
    author = "Danyas"
}

new iNumRound;

public OnPluginStart()
{
    HookEvent("round_end", Event_Round_End, EventHookMode_PostNoCopy);
}

public Event_Round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (++iNumRound == 10)
    {
        iNumRound = 0;
        for(new i = 1; i <= MaxClients; i++)
        {
            new team = GetClientTeam(i);
            if(IsClientInGame(i) && team == 3)
            {
                CS_SwitchTeam(i, 2);
            }
            else if(IsClientInGame(i) && team == 2)
            {
                CS_SwitchTeam(i, 3);
            }
        }
    }
}

 

[AlmazON]

iNumRound = 0;

Так смена команд будет каждые 10 раундов. Оффтоп

Т.е. ни один раз.

А если так и нужно, то при более ранней смене карты (rtv или админом) счёт нарушится и замена наступит куда раньше.
Оффтоп

if(IsClientInGame(i) && team == 3)
{
CS_SwitchTeam(i, 2);
}
else if(IsClientInGame(i)

"Обалденное" двойное написание. :mosking:

 

[Danyas]

Так смена команд будет каждые 10 раундов. Оффтоп

Т.е. ни один раз.

А если так и нужно, то при более ранней смене карты (rtv или админом) счёт нарушится и замена наступит куда раньше.
Оффтоп

"Обалденное" двойное написание. :mosking:

Слепое написание подьехало

#include <cstrike>

public Plugin:myinfo = 
{
    name = "HalfTime Replacer",
    author = "Danyas"
}

new iNumRound;
new iTargRound;
new Handle:hRounds;

public OnPluginStart()
{
    HookEvent("round_end", Event_Round_End, EventHookMode_PostNoCopy);
    hRounds = FindConVar("mp_maxrounds");
    if (hRounds == INVALID_HANDLE) SetFailState("somethink wrong");
    else 
    {
        iTargRound = GetConVarInt(hRounds) / 2 ;
    }
}

public Event_Round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (++iNumRound == iTargRound)
    {
        iNumRound = 0;
        for(new i = 1; i <= MaxClients; i++)
        {
            if(IsClientInGame(i))
            {
                new team = GetClientTeam(i);
                if(team == 3)
                {
                    CS_SwitchTeam(i, 2);
                }
                else if(team == 2)
                {
                    CS_SwitchTeam(i, 3);
                }
            }
        }
    }
}

 

[Dreizehnt]

Слепое написание подьехало

#include <cstrike>

public Plugin:myinfo =
{
    name = "HalfTime Replacer",
    author = "Danyas"
}

new iNumRound;
new iTargRound;
new Handle:hRounds;

public OnPluginStart()
{
    HookEvent("round_end", Event_Round_End, EventHookMode_PostNoCopy);
    hRounds = FindConVar("mp_maxrounds");
    if (hRounds == INVALID_HANDLE) SetFailState("somethink wrong");
    else
    {
        iTargRound = GetConVarInt(hRounds) / 2 ;
    }
}

public Event_Round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (++iNumRound == iTargRound)
    {
        iNumRound = 0;
        for(new i = 1; i <= MaxClients; i++)
        {
            if(IsClientInGame(i))
            {
                new team = GetClientTeam(i);
                if(team == 3)
                {
                    CS_SwitchTeam(i, 2);
                }
                else if(team == 2)
                {
                    CS_SwitchTeam(i, 3);
                }
            }
        }
    }
}

Проверил первый вариант сейчас, работает, спасибо)) Только происходит молниеносно, могу попросить добавить сообщение в чат о смене сторон, может паузу маленькую или это осложнит?

 

[Danyas]

Проверил первый вариант сейчас, работает, спасибо)) Только происходит молниеносно, могу попросить добавить сообщение в чат о смене сторон, может паузу маленькую или это осложнит?

Перед iNumRound = 0;
добавляешь одно из (а можешь и всё сразу)
PrintToChatAll("Смена сторон"); // Вывод в чате
PrintCenterTextAll("Смена сторон"); // Вывод в окне снизу

 

[Dreizehnt]

Перед iNumRound = 0;
добавляешь одно из (а можешь и всё сразу)
PrintToChatAll("Смена сторон"); // Вывод в чате
PrintCenterTextAll("Смена сторон"); // Вывод в окне снизу

Спасибо)) Ещё такой вопросик, команды сменились, а очки команд остались на месте, это уже не сменить, да?

 

[Danyas]

Спасибо)) Ещё такой вопросик, команды сменились, а очки команд остались на месте, это уже не сменить, да?

#include <cstrike>

public Plugin:myinfo = 
{
    name = "HalfTime Replacer",
    author = "Danyas"
}

new iNumRound;
new iTargRound;
new Handle:hRounds;

public OnPluginStart()
{
    HookEvent("round_end", Event_Round_End, EventHookMode_PostNoCopy);
    hRounds = FindConVar("mp_maxrounds");
    if (hRounds == INVALID_HANDLE) SetFailState("somethink wrong");
    else 
    {
        iTargRound = GetConVarInt(hRounds) / 2 ;
    }
}

public Event_Round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (++iNumRound == iTargRound)
    {
        new tempscoret = GetTeamScore(2);
        new tempscorect = GetTeamScore(3);
       
        SetTeamScore(3, tempscoret);
        SetTeamScore(2, tempscorect);
       
        PrintToChatAll("Смена сторон");
        PrintCenterTextAll("Смена сторон");       
        iNumRound = 0;
        for(new i = 1; i <= MaxClients; i++)
        {
            if(IsClientInGame(i))
            {
                new team = GetClientTeam(i);
                if(team == 3)
                {
                    CS_SwitchTeam(i, 2);
                }
                else if(team == 2)
                {
                    CS_SwitchTeam(i, 3);
                }
            }
        }
    }
}

 

[Dreizehnt]

#include <cstrike>

public Plugin:myinfo =
{
    name = "HalfTime Replacer",
    author = "Danyas"
}

new iNumRound;
new iTargRound;
new Handle:hRounds;

public OnPluginStart()
{
    HookEvent("round_end", Event_Round_End, EventHookMode_PostNoCopy);
    hRounds = FindConVar("mp_maxrounds");
    if (hRounds == INVALID_HANDLE) SetFailState("somethink wrong");
    else
    {
        iTargRound = GetConVarInt(hRounds) / 2 ;
    }
}

public Event_Round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (++iNumRound == iTargRound)
    {
        new tempscoret = GetTeamScore(2);
        new tempscorect = GetTeamScore(3);
      
        SetTeamScore(3, tempscoret);
        SetTeamScore(2, tempscorect);
      
        PrintToChatAll("Смена сторон");
        PrintCenterTextAll("Смена сторон");      
        iNumRound = 0;
        for(new i = 1; i <= MaxClients; i++)
        {
            if(IsClientInGame(i))
            {
                new team = GetClientTeam(i);
                if(team == 3)
                {
                    CS_SwitchTeam(i, 2);
                }
                else if(team == 2)
                {
                    CS_SwitchTeam(i, 3);
                }
            }
        }
    }
}

Благодарю, вроде бы всё что хотел :D
--- Добавлено позже ---
Теперь с ошибкой компилируется.. Возможно с ошибкой написаны функции?
Оффтоп

/home/groups/sourcemod/upload_tmp/phppziHmN.sp(28) : error 017: undefined symbol "GetTeamScore"
/home/groups/sourcemod/upload_tmp/phppziHmN.sp(29) : error 017: undefined symbol "GetTeamScore"
/home/groups/sourcemod/upload_tmp/phppziHmN.sp(31) : error 017: undefined symbol "SetTeamScore"
/home/groups/sourcemod/upload_tmp/phppziHmN.sp(32) : error 017: undefined symbol "SetTeamScore"

 

[AlmazON]

SetTeamScore(3, tempscoret);
SetTeamScore(2, tempscorect);

Ничего так не выйдет. Очки сбросятся на обычные уже в следующем раунде.

PrintToChatAll("Смена сторон");
PrintCenterTextAll("Смена сторон");

А в том же цикле, где стороны меняешь - никак сделать?)

 

[Danyas]

Ничего так не выйдет. Очки сбросятся на обычные уже в следующем раунде.
А в том же цикле, где стороны меняешь - никак сделать?)

Сделал что бы было понятней.

А почему через SetTeamScore ничего не выйдет? Из-за особенностей кысыго?

 

[AlmazON]

Из-за особенностей кысыго?

Вроде того. Игра сохраняет их и устанавливает заново. Поэтому, лучше тогда просто:

Спойлер: HalfTime Replacer

#include <cstrike>

public Plugin:myinfo =
{
    name = "HalfTime Replacer",
    author = "Danyas"
}

new iNumRound;
new iTargRound;

public OnPluginStart()
{
    decl Handle:hRounds;
    if ((hRounds = FindConVar("mp_maxrounds")) == INVALID_HANDLE) SetFailState("somethink wrong");
    HookEvent("round_end", Event_Round_End, EventHookMode_PostNoCopy);
    iTargRound = GetConVarInt(hRounds) / 2;
    HookConVarChange(hRounds, Change_CvarRounds);
}

public Change_CvarRounds(Handle:hRounds, String:oldValue[], String:newValue[]) iTargRound = GetConVarInt(hRounds) / 2;

public OnConfigsExecuted() iNumRound = 0;

public Event_Round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (++iNumRound == iTargRound)
    {
        for (new i = 1; i <= MaxClients; ++i)
        {
            if (IsClientInGame(i))
            {
                switch (GetClientTeam(i))
                {
                    case 3:
                    {
                        CS_SwitchTeam(i, 2);
                        //PrintToChat(i, "Вы перемещены за команду Т.");
                    }
                    case 2:
                    {
                        CS_SwitchTeam(i, 3);
                        //PrintToChat(i, "Вы перемещены за команду КТ.");
                    }
                }
                PrintCenterText(i, "Смена сторон!");
                PrintToChat(i, "Смена сторон!");
            }
        }
    }
}

В этом варианте есть особенность (в плюс или минус): если смена сторон уже была, а квар изменился в большую сторону, то смена сторон может произойти ещё раз по новому значению. Оффтоп

Если не требуется, нужно чуть изменить.

 

[Dreizehnt]

Теперь с ошибкой компилируется.. Возможно с ошибкой написаны
Оффтоп

/home/groups/sourcemod/upload_tmp/phppziHmN.sp(28) : error 017: undefined symbol "GetTeamScore"
/home/groups/sourcemod/upload_tmp/phppziHmN.sp(29) : error 017: undefined symbol "GetTeamScore"
/home/groups/sourcemod/upload_tmp/phppziHmN.sp(31) : error 017: undefined symbol "SetTeamScore"
/home/groups/sourcemod/upload_tmp/phppziHmN.sp(32) : error 017: undefined symbol "SetTeamScore"

Вроде того. Игра сохраняет их и устанавливает заново. Поэтому, лучше тогда просто:

Спойлер: HalfTime Replacer

#include <cstrike>

public Plugin:myinfo =
{
    name = "HalfTime Replacer",
    author = "Danyas"
}

new iNumRound;
new iTargRound;

public OnPluginStart()
{
    decl Handle:hRounds;
    if ((hRounds = FindConVar("mp_maxrounds")) == INVALID_HANDLE) SetFailState("somethink wrong");
    HookEvent("round_end", Event_Round_End, EventHookMode_PostNoCopy);
    iTargRound = GetConVarInt(hRounds) / 2;
    HookConVarChange(hRounds, Change_CvarRounds);
}

public Change_CvarRounds(Handle:hRounds, String:oldValue[], String:newValue[]) iTargRound = GetConVarInt(hRounds) / 2;

public OnConfigsExecuted() iNumRound = 0;

public Event_Round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (++iNumRound == iTargRound)
    {
        for (new i = 1; i <= MaxClients; ++i)
        {
            if (IsClientInGame(i))
            {
                switch (GetClientTeam(i))
                {
                    case 3:
                    {
                        CS_SwitchTeam(i, 2);
                        //PrintToChat(i, "Вы перемещены за команду Т.");
                    }
                    case 2:
                    {
                        CS_SwitchTeam(i, 3);
                        //PrintToChat(i, "Вы перемещены за команду КТ.");
                    }
                }
                PrintCenterText(i, "Смена сторон!");
                PrintToChat(i, "Смена сторон!");
            }
        }
    }
}

В этом варианте есть особенность (в плюс или минус): если смена сторон уже была, а квар изменился в большую сторону, то смена сторон может произойти ещё раз по новому значению. Оффтоп

Если не требуется, нужно чуть изменить.

Спасибо в очередной раз, работает как мне показалось, надо только убедиться, но у меня на 15 раунде смена, не скоро это)))

 

[AlmazON]

у меня на 15 раунде смена, не скоро это

Вбей квар mp_maxrounds в консоль сервера на маленькое значение и плагин сработает. Потом на обычное - опять сработает. В отличии от варианта @Danyas, этот будет слушаться квара в "онлайн"-режиме.

 

[Dreizehnt]

Вбей квар mp_maxrounds в консоль сервера на маленькое значение и плагин сработает. Потом на обычное - опять сработает. В отличии от варианта @Danyas, этот будет слушаться квара в "онлайн"-режиме.

Сейчас ничего не менял, так же на 15 отследил, но теперь счет команд не перенесся.